Golo <3 Vert.x

golo.x.golo

module golo.x

import io.vertx.core.Vertx
import io.vertx.core.http.HttpServer
import io.vertx.ext.web.Router
import io.vertx.ext.web.handler

let vertx = Vertx.vertx()

function createHttpServer = {
  return vertx: createHttpServer()
}

function getRouter = {
  let router = Router.router(vertx)
  router: route(): handler(BodyHandler.create())
  return router
}

function startHttpServer = |server, router, port, staticPath| {
  router: route(staticPath): handler(StaticHandler.create())
  server: requestHandler(|httpRequest| -> router: accept(httpRequest)): listen(port)
  println("HttpServer is listening on " + port)
  return server
}

function main = |args| {

  let server = createHttpServer()
  let router = getRouter()

  router: get("/hello"): handler(|context| {
    let response = context: response()
    response: putHeader("content-type", "text/plain")
    response: end("Hello World from Golo.x-Web!")
  })

  router: get("/hi"): handler(|context| {
    let response = context: response()
    response: putHeader("content-type", "application/json")
    response: end(JSON.stringify(map[
      ["message","Hello World from Golo.x-Web!"]
    ]))
  })

  startHttpServer(
    server=server,
    router=router,
    port=9090,
    staticPath="/*"
  )
}