Last active
April 15, 2020 19:37
-
-
Save kaimingguo/b20cc965bfc672e77f0926b88277f54d to your computer and use it in GitHub Desktop.
CMake find SDL2 library modules
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying | |
# file Copyright.txt or https://cmake.org/licensing for details. | |
#.rst: | |
# FindSDL2 | |
# -------- | |
# | |
# Locate SDL2 library | |
# | |
# This module defines | |
# | |
# :: | |
# | |
# SDL2_LIBRARIES, the name of the library to link against | |
# SDL2_FOUND, if false, do not try to link to SDL | |
# SDL2_INCLUDE_DIRS, where to find SDL.h | |
# SDL2_VERSION, human-readable string containing the version of SDL | |
# | |
# | |
# | |
# This module responds to the flag: | |
# | |
# :: | |
# | |
# SDL2_BUILDING_LIBRARY | |
# If this is defined, then no SDL2_main will be linked in because | |
# only applications need main(). | |
# Otherwise, it is assumed you are building an application and this | |
# module will attempt to locate and set the proper link flags | |
# as part of the returned SDL2_LIBRARY variable. | |
# | |
# | |
# | |
# Don't forget to include SDLmain.h and SDLmain.m your project for the | |
# OS X framework based version. (Other versions link to -lSDLmain which | |
# this module will try to find on your behalf.) Also for OS X, this | |
# module will automatically add the -framework Cocoa on your behalf. | |
# | |
# | |
# | |
# Additional Note: If you see an empty SDL2_LIBRARY_TEMP in your | |
# configuration and no SDL2_LIBRARY, it means CMake did not find your SDL | |
# library (SDL.dll, libsdl.so, SDL.framework, etc). Set | |
# SDL2_LIBRARY_TEMP to point to your SDL library, and configure again. | |
# Similarly, if you see an empty SDL2MAIN_LIBRARY, you should set this | |
# value as appropriate. These values are used to generate the final | |
# SDL2_LIBRARY variable, but when these values are unset, SDL2_LIBRARY | |
# does not get created. | |
# | |
# | |
# | |
# $SDL2_DIR is an environment variable that would correspond to the | |
# ./configure --prefix=$SDL2_DIR used in building SDL. l.e.galup 9-20-02 | |
# | |
# Modified by Eric Wing. Added code to assist with automated building | |
# by using environmental variables and providing a more | |
# controlled/consistent search behavior. Added new modifications to | |
# recognize OS X frameworks and additional Unix paths (FreeBSD, etc). | |
# Also corrected the header search path to follow "proper" SDL | |
# guidelines. Added a search for SDLmain which is needed by some | |
# platforms. Added a search for threads which is needed by some | |
# platforms. Added needed compile switches for MinGW. | |
# | |
# On OSX, this will prefer the Framework version (if found) over others. | |
# People will have to manually change the cache values of SDL2_LIBRARY to | |
# override this selection or set the CMake environment | |
# CMAKE_INCLUDE_PATH to modify the search paths. | |
# | |
# Note that the header path has changed from SDL2/SDL.h to just SDL.h | |
# This needed to change because "proper" SDL convention is #include | |
# "SDL.h", not <SDL2/SDL.h>. This is done for portability reasons | |
# because not all systems place things in SDL2/ (see FreeBSD). | |
#============================================================================= | |
# Copyright 2003-2009 Kitware, Inc. | |
# | |
# Distributed under the OSI-approved BSD License (the "License"); | |
# see accompanying file Copyright.txt for details. | |
# | |
# This software is distributed WITHOUT ANY WARRANTY; without even the | |
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. | |
# See the License for more information. | |
#============================================================================= | |
# (To distribute this file outside of CMake, substitute the full | |
# License text for the above reference.) | |
# message("<FindSDL2.cmake>") | |
if(NOT SDL2_DIR) | |
set(SDL2_DIR "" CACHE PATH "SDL2 directory") | |
endif() | |
set(SDL2_SEARCH_PATHS | |
~/Library/Frameworks | |
/Library/Frameworks | |
/usr/local | |
/usr | |
/sw # Fink | |
/opt/local # DarwinPort | |
/opt/csw # Blastwave | |
/opt | |
${SDL2_DIR} | |
) | |
find_path(SDL2_INCLUDE_DIR SDL.h | |
HINTS | |
$ENV{SDL2_DIR} | |
PATH_SUFFIXES include/SDL2 include | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
if(CMAKE_SIZEOF_VOID_P EQUAL 8) | |
set(PATH_SUFFIXES lib64 lib/x64 lib) | |
else() | |
set(PATH_SUFFIXES lib/x86 lib) | |
endif() | |
find_library(SDL2_LIBRARY_TEMP | |
NAMES SDL2 | |
HINTS | |
$ENV{SDL2_DIR} | |
PATH_SUFFIXES ${PATH_SUFFIXES} | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
# Hide this cache variable from the user, it's an internal implementation | |
# detail. The documented library variable for the user is SDL2_LIBRARY | |
# which is derived from SDL2_LIBRARY_TEMP further below. | |
set_property(CACHE SDL2_LIBRARY_TEMP PROPERTY TYPE INTERNAL) | |
if(NOT SDL2_BUILDING_LIBRARY) | |
if(NOT SDL2_INCLUDE_DIR MATCHES ".frameworks") | |
# Non-OS X framework versions expect you to also dynamically link to | |
# SDLmain. This is mainly for Windows and OS X. Other (Unix) platforms | |
# seem to provide SDLmain for compatibility even though they don't | |
# necessarily need it. | |
find_library(SDL2MAIN_LIBRARY | |
NAMES SDL2main | |
HINTS | |
$ENV{SDL2_DIR} | |
PATH_SUFFIXES ${PATH_SUFFIXES} | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
endif() | |
endif() | |
# SDL may require threads on your system. | |
# The Apple build may not need an explicit flag because one of the | |
# frameworks may already provide it. | |
# But for non-OSX systems, I will use the CMake Threads package. | |
if(NOT APPLE) | |
find_package(Threads) | |
endif() | |
# MinGW needs an additional link flag, -mwindows | |
# It's total link flags should look like -lmingw32 -lSDLmain -lSDL -mwindows | |
if(MINGW) | |
set(MINGW32_LIBRARY mingw32 "-mwindows" CACHE STRING "link flags for MinGW") | |
endif() | |
if(SDL2_LIBRARY_TEMP) | |
# For SDL2main | |
if(NOT SDL2_BUILDING_LIBRARY) | |
if(SDL2MAIN_LIBRARY) | |
set(SDL2_LIBRARY_TEMP ${SDL2MAIN_LIBRARY} ${SDL2_LIBRARY_TEMP}) | |
endif() | |
endif() | |
# For OS X, SDL2 uses Cocoa as a backend so it must link to Cocoa. | |
# CMake doesn't display the -framework Cocoa string in the UI even | |
# though it actually is there if I modify a pre-used variable. | |
# I think it has something to do with the CACHE STRING. | |
# So I use a temporary variable until the end so I can set the | |
# "real" variable in one-shot. | |
if(APPLE) | |
set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} "-framework Cocoa") | |
endif() | |
# For threads, as mentioned Apple doesn't need this. | |
# In fact, there seems to be a problem if I used the Threads package | |
# and try using this line, so I'm just skipping it entirely for OS X. | |
if(NOT APPLE) | |
set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} ${CMAKE_THREAD_LIBS_INIT}) | |
endif() | |
# For MinGW library | |
if(MINGW) | |
set(SDL2_LIBRARY_TEMP ${MINGW32_LIBRARY} ${SDL2_LIBRARY_TEMP}) | |
endif() | |
# Set the final string here so the GUI reflects the final state. | |
set(SDL2_LIBRARY ${SDL2_LIBRARY_TEMP} CACHE STRING "Where the SDL2 library can be found") | |
# Set the temp variable to INTERNAL so it is not seen in the CMake GUI | |
set(SDL2_LIBRARY_TEMP "${SDL2_LIBRARY_TEMP}" CACHE INTERNAL "") | |
endif() | |
if(SDL2_INCLUDE_DIR AND EXISTS "${SDL2_INCLUDE_DIR}/SDL_version.h") | |
file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+[0-9]+$") | |
file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MINOR_VERSION[ \t]+[0-9]+$") | |
file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_PATCHLEVEL_LINE REGEX "^#define[ \t]+SDL_PATCHLEVEL[ \t]+[0-9]+$") | |
string(REGEX REPLACE "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MAJOR "${SDL2_VERSION_MAJOR_LINE}") | |
string(REGEX REPLACE "^#define[ \t]+SDL_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MINOR "${SDL2_VERSION_MINOR_LINE}") | |
string(REGEX REPLACE "^#define[ \t]+SDL_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL2_PATCHLEVEL "${SDL2_PATCHLEVEL_LINE}") | |
set(SDL2_VERSION ${SDL2_VERSION_MAJOR}.${SDL2_VERSION_MINOR}.${SDL2_PATCHLEVEL}) | |
unset(SDL2_VERSION_MAJOR_LINE) | |
unset(SDL2_VERSION_MINOR_LINE) | |
unset(SDL2_PATCHLEVEL_LINE) | |
unset(SDL2_VERSION_MAJOR) | |
unset(SDL2_VERSION_MINOR) | |
unset(SDL2_PATCHLEVEL) | |
endif() | |
set(SDL2_LIBRARIES ${SDL2_LIBRARY} ${SDL2MAIN_LIBRARY}) | |
set(SDL2_INCLUDE_DIRS ${SDL2_INCLUDE_DIR}) | |
# message("</FindSDL2.cmake>") | |
include(FindPackageHandleStandardArgs) | |
FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL2 | |
REQUIRED_VARS SDL2_LIBRARIES SDL2_INCLUDE_DIRS | |
VERSION_VAR SDL2_VERSION) |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying | |
# file Copyright.txt or https://cmake.org/licensing for details. | |
#.rst: | |
# FindSDL2_image | |
# -------- | |
# | |
# Locate SDL2_image library | |
# | |
# This module defines | |
# | |
# :: | |
# | |
# SDL2_IMAGE_LIBRARIES, the name of the library to link against | |
# SDL2_IMAGE_FOUND, if false, do not try to link to SDL | |
# SDL2_IMAGE_INCLUDE_DIRS, where to find SDL.h | |
# SDL2_IMAGE_VERSION, human-readable string containing the version of SDL_image | |
# | |
# | |
# | |
# This module responds to the flag: | |
# | |
# :: | |
# | |
# $SDL2_DIR is an environment variable that would correspond to the | |
# ./configure --prefix=$SDL2_DIR used in building SDL. l.e.galup 9-20-02 | |
# | |
# Created by Eric Wing. This was influenced by the FindSDL_image.cmake | |
# module, but with modifications to recognize OS X frameworks and | |
# additional Unix paths (FreeBSD, etc). | |
#============================================================================= | |
# Copyright 2003-2009 Kitware, Inc. | |
# | |
# Distributed under the OSI-approved BSD License (the "License"); | |
# see accompanying file Copyright.txt for details. | |
# | |
# This software is distributed WITHOUT ANY WARRANTY; without even the | |
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. | |
# See the License for more information. | |
#============================================================================= | |
# (To distribute this file outside of CMake, substitute the full | |
# License text for the above reference.) | |
# message("<FindSDL2_image.cmake>") | |
if(NOT SDL2_DIR) | |
set(SDL2_DIR "" CACHE PATH "SDL2 directory") | |
endif() | |
set(SDL2_IMAGE_SEARCH_PATHS | |
~/Library/Frameworks | |
/Library/Frameworks | |
/usr/local | |
/usr | |
/sw # Fink | |
/opt/local # DarwinPort | |
/opt/csw # Blastwave | |
/opt | |
${SDL2_DIR} | |
) | |
find_path(SDL2_IMAGE_INCLUDE_DIR SDL_image.h | |
HINTS | |
$ENV{SDL2_DIR} | |
PATH_SUFFIXES include/SDL2 include | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
if(CMAKE_SIZEOF_VOID_P EQUAL 8) | |
set(PATH_SUFFIXES lib64 lib/x64 lib) | |
else() | |
set(PATH_SUFFIXES lib/x86 lib) | |
endif() | |
find_library(SDL2_IMAGE_LIBRARY | |
NAMES SDL2_image | |
HINTS | |
$ENV{SDL2_DIR} | |
PATH_SUFFIXES ${PATH_SUFFIXES} | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
if(SDL2_IMAGE_INCLUDE_DIR AND EXISTS "${SDL2_IMAGE_INCLUDE_DIR}/SDL_image.h") | |
file(STRINGS "${SDL2_IMAGE_INCLUDE_DIR}/SDL_image.h" VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_IMAGE_MAJOR_VERSION[ \t]+[0-9]+$") | |
file(STRINGS "${SDL2_IMAGE_INCLUDE_DIR}/SDL_image.h" VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_IMAGE_MINOR_VERSION[ \t]+[0-9]+$") | |
file(STRINGS "${SDL2_IMAGE_INCLUDE_DIR}/SDL_image.h" PATCHLEVEL_LINE REGEX "^#define[ \t]+SDL_IMAGE_PATCHLEVEL[ \t]+[0-9]+$") | |
string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" VERSION_MAJOR "${VERSION_MAJOR_LINE}") | |
string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" VERSION_MINOR "${VERSION_MINOR_LINE}") | |
string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" PATCHLEVEL "${PATCHLEVEL_LINE}") | |
set(SDL2_IMAGE_VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${PATCHLEVEL}) | |
unset(VERSION_MAJOR_LINE) | |
unset(VERSION_MINOR_LINE) | |
unset(PATCHLEVEL_LINE) | |
unset(VERSION_MAJOR) | |
unset(VERSION_MINOR) | |
unset(PATCHLEVEL) | |
endif() | |
set(SDL2_IMAGE_LIBRARIES ${SDL2_IMAGE_LIBRARY}) | |
set(SDL2_IMAGE_INCLUDE_DIRS ${SDL2_IMAGE_INCLUDE_DIR}) | |
# message("</FindSDL2_image.cmake>") | |
include(FindPackageHandleStandardArgs) | |
FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL2_image | |
REQUIRED_VARS SDL2_IMAGE_LIBRARIES SDL2_IMAGE_INCLUDE_DIRS | |
VERSION_VAR SDL2_IMAGE_VERSION) | |
mark_as_advanced(SDL2_IMAGE_LIBRARY SDL2_IMAGE_INCLUDE_DIR) |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
https://trenki2.github.io/blog/2017/06/02/using-sdl2-with-cmake/ | |
https://github.com/tcbrindle/sdl2-cmake-scripts |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment