.envrc

use_nix

nixpkgs-version.json

{
  "url": "https://github.com/nixos/nixpkgs.git",
  "rev": "fddd90e9eaf7063156721ac7a296b2f219edb92e",
  "date": "2018-07-19T00:35:09-04:00",
  "sha256": "1016470d5xicrcia2ljjyqdpm95103a3a3kmhj857z014lxfvy6f",
  "fetchSubmodules": false
}

shell.nix

let
  hostPkgs = import <nixpkgs> {};
  # Look here for information about how to generate `nixpkgs-version.json`.
  #  → https://nixos.wiki/wiki/FAQ/Pinning_Nixpkgs
  pinnedVersion = hostPkgs.lib.importJSON ./lib/nix/nixpkgs-version.json;
  pinnedPkgs = hostPkgs.fetchFromGitHub {
    owner = "NixOS";
    repo = "nixpkgs";
    inherit (pinnedVersion) rev sha256;
  };

  bazel = (import pinnedPkgs {}).bazel.overrideAttrs (oa: rec {
    enableNixHacks = true;
  });

  minikube_0_25_2 = (import pinnedPkgs {}).minikube.overrideAttrs (oldAttrs: rec {
    version = "0.25.2";
    src = hostPkgs.fetchFromGitHub {
      owner  = "kubernetes";
      repo   = "minikube";
      rev    = "v${version}";
      sha256 = "1h8sxs6xxmli7xkb33kdl4nyn1sgq2b8b2d6aj5wim11ric3l7pb";
    };
  });
in

# This allows overriding nixpkgs by passing `--arg nixpkgs ...`
{ nixpkgs ? import pinnedPkgs {} }:

nixpkgs.mkShell {
  buildInputs = with nixpkgs; [
    awscli
    bazel
    dep
    go
    jq
    kubectl
    kubernetes-helm
    minikube_0_25_2
    nodejs-8_x
    python2Full
    python3Full
    terraform-full
    unixtools.xxd
    yarn
  ];
}