shell.nix

let
  hostPkgs = import <nixpkgs> {};
  # Look here for information about how to generate `nixpkgs-version.json`.
  #  → https://nixos.wiki/wiki/FAQ/Pinning_Nixpkgs
  pinnedVersion = hostPkgs.lib.importJSON ./lib/nix/nixpkgs-version.json;
  pinnedPkgs = import (hostPkgs.fetchFromGitHub {
    owner = "NixOS";
    repo = "nixpkgs";
    inherit (pinnedVersion) rev sha256;
  }) {};

  minikube_0_25_2 = pinnedPkgs.minikube.overrideAttrs (oldAttrs: rec {
    version = "0.25.2";
    src = hostPkgs.fetchFromGitHub {
      owner  = "kubernetes";
      repo   = "minikube";
      rev    = "v${version}";
      sha256 = "1h8sxs6xxmli7xkb33kdl4nyn1sgq2b8b2d6aj5wim11ric3l7pb";
    };
  });
in

# This allows overriding nixpkgs by passing `--arg nixpkgs ...`
{ nixpkgs ? pinnedPkgs, lib ? nixpkgs.lib }:

nixpkgs.mkShell {
  buildInputs = with nixpkgs; with lib; [
    awscli
    bazel
    delve
    dep
    go
    go-jira
    jq
    kubectl
    kubernetes-helm
    minikube_0_25_2
    python27Packages.docker_compose
    python2Full
    python3Full
  ] ++ optionals stdenv.isDarwin [
    gcc
  ];
}