Example AngularJS controller in Coffeescript

base.coffee

class @Base
  @inject: (args...) ->
    if args.length is 1
      args = args[0].split ' '
    if @$inject?.length > 0
      for arg in args
        @$inject.push arg
    else
      @$inject = args

  @register: (app, type, name) ->
    app[type] name, @

  constructor: (args...) ->
    for key, index in @constructor.$inject
      @[key] = args[index]

    @initialize?()

tickets.coffee

'use strict'

class TicketsController extends Base
  @register angular.module('fauve'), 'controller', 'TicketsController'

  @inject '$scope'

  initialize: ->
    @$scope.data = [
      { id: 1, title: 'Hello', description: 'World' },
      { id: 2, title: 'Bye', description: 'World'}
    ]

tickets.js

'use strict'

angular.module('fauve')
  .controller('TicketsController', [
     '$scope',
     function ($scope) {
       $scope.data = [
          { id: 1, title: 'Hello', description: 'World' },
          { id: 2, title: 'Bye', description: 'World'}
         ]
     }
    ]);
  

Based on http://www.devign.me/angular-dot-js-coffeescript-controller-base-class