Locate Browser Executable Paths

locatebrowserpaths.bat

@echo off
setlocal

rem SET PHANTOMJS_BIN=%AppData%\npm\node_modules\phantomjs\lib\phantom\phantomjs.exe
REM SET CHROME_BIN=C:\Program Files (x86)\Google\Chrome\Application\chrome.exe
rem SET CHROME_BIN=%LOCALAPPDATA%\Google\Chrome\Application\chrome.exe
REM SET FIREFOX_BIN=C:\Program Files (x86)\Mozilla Firefox\firefox.exe

SET BROWSERPATH=
call :loc Chrome HKEY_CLASSES_ROOT\ChromeHTML\shell\open\command
IF DEFINED BROWSERPATH      SET CHROME_BIN=%BROWSERPATH%
IF DEFINED BROWSERPATH ECHO SET CHROME_BIN=%BROWSERPATH%

SET BROWSERPATH=
call :loc IE HKEY_CLASSES_ROOT\IE.HTTP\shell\open\command
IF DEFINED BROWSERPATH      SET IE_BIN=%BROWSERPATH%
IF DEFINED BROWSERPATH ECHO SET IE_BIN=%BROWSERPATH%

SET BROWSERPATH=
call :loc FireFox HKEY_CLASSES_ROOT\FirefoxURL\shell\open\command
IF DEFINED BROWSERPATH      SET FIREFOX_BIN=%BROWSERPATH%
IF DEFINED BROWSERPATH ECHO SET FIREFOX_BIN=%BROWSERPATH%

SET BROWSERPATH=
call :loc Opera HKEY_CLASSES_ROOT\OperaStable\shell\open\command
IF DEFINED BROWSERPATH      SET OPERA_BIN=%BROWSERPATH%
IF DEFINED BROWSERPATH ECHO SET OPERA_BIN=%BROWSERPATH%

SET BROWSERPATH=
call :loc Safari HKEY_CLASSES_ROOT\SafariURL\shell\open\command
IF DEFINED BROWSERPATH      SET SAFARI_BIN=%BROWSERPATH%
IF DEFINED BROWSERPATH ECHO SET SAFARI_BIN=%BROWSERPATH%

goto :eof


:loc
Echo Looking for %1
FOR /F "usebackq skip=2 tokens=*" %%A IN (`REG QUERY %2`) DO call :try %%A
goto :eof

:try
if not exist %3 goto :eof
SET BROWSERPATH=%3
goto :eof