lib32-virtualgl

PKGBUILD

# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: FigoDaPaura <ffigoDaPaura>

pkgname=lib32-virtualgl
pkgver=2.5
pkgrel=1
pkgdesc="32-bit serverside components for 64-bit VirtualGL servers"
arch=('x86_64')
url="http://virtualgl.org"
license=('LGPL')
makedepends=('lib32-libxv' 'lib32-glu' 'virtualgl' 'lib32-libjpeg-turbo' 'cmake' 'gcc-multilib' 'lib32-mesa' 'lib32-mesa-libgl')
depends=('virtualgl' 'lib32-libxv' 'lib32-glu' 'lib32-turbojpeg')
source=("https://github.com/VirtualGL/virtualgl/archive/${pkgver}.tar.gz")
sha1sums=('c4bfa185b36c2f4938aa0be5223b920aa1c037c6')
 
build() {
  cd "$srcdir/virtualgl-$pkgver"
 
  export CFLAGS="-m32"
  export CXXFLAGS="-m32"
  export LDFLAGS="-m32"
 
  mkdir -p build && cd build
 
  cmake .. \
      -DCMAKE_INSTALL_PREFIX=/usr/share \
      -DTJPEG_INCLUDE_DIR=/usr/include \
      -DTJPEG_LIBRARY=/usr/lib32/libturbojpeg.so \
      -DVGL_LIBDIR=/usr/lib32 \
      -DVGL_BINDIR=/usr/bin \
      -DVGL_DOCDIR=/usr/share/doc/${pkgname}
  make
}
 
package() {
  cd "$srcdir/virtualgl-$pkgver/build"
  make install DESTDIR="$pkgdir"

  cd "$pkgdir/usr"
  mv bin/glxspheres glxspheres32
  rm -rf bin
  mkdir -p bin
  mv glxspheres32 bin/
 
  cd "$pkgdir/usr/share"
  rm -rf doc
  rm -rf include
}