clojure.test helper function for Malli

gistfile1.txt

(def conforming? 'conforming?)

(defmethod clojure.test/assert-expr 'conforming? [msg form]
  ;; (is (conforming? schema structure))
  ;; Asserts that evaluating structure conforms to the given malli schema
  `(let [schema# ~(nth form 1)
         structure# ~(nth form 2)]
     (try (let [result# (m/validate schema# structure#)]
            (if result#
              (do-report {:type :pass, :message ~msg,
                          :expected '~(nth form 1), :actual structure#})
              (let [explanation# (m/explain schema# structure#)
                    msg# (str "Failed to conform schema:\n"
                              (with-out-str
                                (clojure.pprint/pprint
                                  (me/humanize explanation#))))
                    value# (:value explanation#)]
                (do-report {:type     :fail
                            :message  msg#,
                            :expected '~(nth form 1)
                            :actual   value#}))))
          (catch Exception e#
            (do-report {:type     :fail, :message ~msg,
                        :expected '~form, :actual e#})
            e#))))