サーバーワークスのbackboneの記事のコードを自分なりに書きなおしてみたもの http://blog.serverworks.co.jp/tech/2011/10/24/backbone-jscoffeescript%E3%82%92%E8%A9%A6%E3%81%97%E3%81%A6%E3%81%BF%E3%82%8B/

user.coffee

class User extends Backbone.Model
  validate: (attr) ->
    if attr.name is ''
      return '一文字以上名前を入力してください'

class Users extends Backbone.Collection
  model: User
  url: '/users'

class UserView extends Backbone.View
  events:
    'click .remove-user': 'del'

  del: ->
    @model.destroy
      success: => @remove()

  template: _.template '<%- name %><button class="remove-user">Remove</button>'
  render: ->
    $(@el).append @template(@model.toJSON())
    @

class UsersView extends Backbone.View
  el: 'body'
  events:
    'click #add-user' : 'createUser'

  initialize: ->
    @collection.bind 'reset', @reset, @
    @collection.bind 'add', @addOne, @
    @collection.fetch()

  reset: (items) ->
    items.each (i) => @addOne i

  addOne: (item) ->
    view = new UserView
      model: item
    @$('#list').append view.render().el

  createUser: ->
    $userName = $('#user_name')
    data =
      name: $userName.val()
    @collection.create data,
      success: ->
        $userName.val ''
      error: (model, error) ->
        alert error

new UsersView
  collection: new Users