cmd batch file to set graalvm environment variables

graalenv.bat

@echo off

set GRAALVM_BASE=D:\opt\graalvm
set GRAALVM_PATH_TMP=%GRAALVM_BASE%\graalpath.tmp
setlocal enabledelayedexpansion

echo.
echo =====================================
echo 🍵 Graalvm Environment Setting Helper
echo 🍵 Graalvm Base Path=%GRAALVM_BASE%
echo =====================================
echo.

set "folderList="
set "count=0"
for /d %%D in (D:\opt\graalvm\*) do (
  set "folderName=%%~nxD"
  if "!folderName:~0,7!"=="graalvm" (
    set /a "count+=1"
    set "folderList[!count!]=%%~D"
  )
)

rem echo ## count= %count%

if %count% gtr 0 (
  echo Folders starting with "graalvm" are:
  for /l %%i in (1,1,%count%) do (
    call echo %%i^) %%folderList[%%i]%%
  )

  set /p "choice=Enter the number of your choice: "

  if "!choice!" geq "1" if "!choice!" leq "!count!" (
    set "selectedFolderIndex=!choice!"
    for /l %%i in (1,1,!count!) do (
      if %%i==!selectedFolderIndex! (
        set "selectedFolder=!folderList[%%i]!"
        echo You have chosen folder number !choice!: !selectedFolder!
      )
    )
    rem echo !selectedFolder! > %GRAALVM_PATH_TMP%
	> %GRAALVM_PATH_TMP% ( echo !selectedFolder! )
  ) else (
    echo ⚠️ Invalid choice.
	exit
  )
) else (
  echo No folders starting with "graalvm" found.
  exit
)

endlocal


set /p selectedFolder=<%GRAALVM_PATH_TMP%
set selectedFolder=%selectedFolder:~0,-1%
del %GRAALVM_PATH_TMP%

rem Remove last 3 characters
rem echo ###%selectedFolder:~0,-1%###
rem show last three characters
rem echo %selectedFolder:~-3%

echo.
echo 👉 Use this GraalVM: ###%selectedFolder%###
echo 👉 Setting PATH, JAVA_HOME as following:

set PATH=%selectedFolder%\bin;%PATH%
rem echo 👉 PATH= %PATH%
set JAVA_HOME=%selectedFolder%

echo 👉 JAVA_HOME=%JAVA_HOME%
echo 👉 where JAVA binary:
where java
echo 👉 Java version:
java -version