reruns all the generators for your project, overwriting everything

ember-cli-regenerate-files.bat

if "%1"=="" goto :eof
setlocal enabledelayedexpansion
pushd %1\app
echo Set WshShell = Wscript.CreateObject("Wscript.Shell")>commands.vbs
echo WshShell.SendKeys "pushd %1{ENTER}">>commands.vbs
for /d %%d in (*) do (
	if not "%%d"=="instance-initializers" if not %%d==locales if not %%d==styles if not %%d==templates if not "%%d"=="torii-adapters" (
		pushd %%d
		set folderName=%%d
		set generator=!folderName:~0,-1!
		for /r %%i in (*) do (
			set fullPath=%%i
			set localPath=!fullPath:%CD%\%%d\=!
			set file=!localPath:.js=!
			if not !file!==.gitkeep (
				set command=ember g !generator! !file!
				echo WshShell.SendKeys "!command!{ENTER}">>../commands.vbs
				echo WshShell.SendKeys "{ENTER}">>../commands.vbs
				echo WshShell.SendKeys "{ENTER}">>../commands.vbs
				echo WshShell.SendKeys "{ENTER}">>../commands.vbs
			)
		)
		popd
	)
)
echo WshShell.SendKeys "popd{ENTER}">>commands.vbs
commands.vbs %1
del commands.vbs
popd