basiliskii-git: updated PKGBUILD for config.rpath issue

configure.ac.patch

--- src/macemu/BasiliskII/src/Unix/configure.ac 2021-01-23 22:21:57.989814552 -0500
+++ configure.ac    2021-01-23 22:33:55.409812229 -0500
@@ -483,10 +483,6 @@
   AM_PATH_GTK(1.2.0, [
     GUI_CFLAGS="$GTK_CFLAGS"
     GUI_LIBS="$GTK_LIBS"
-    dnl somehow, <gnome-i18n.h> would redefine gettext() to nothing if
-    dnl ENABLE_NLS is not set, thusly conflicting with C++ <string> which
-    dnl includes <libintl.h>
-    AM_GNU_GETTEXT([external])
     B2_PATH_GNOMEUI([
       AC_DEFINE(HAVE_GNOMEUI, 1, [Define if libgnomeui is available.])
       GUI_CFLAGS="$GUI_CFLAGS $GNOMEUI_CFLAGS"

PKGBUILD

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: William Termini <aur@termini.me>

pkgname=basiliskii-git
pkgver=r2667.4671258b
pkgrel=1
pkgdesc="Open Source 68k Macintosh Emulator"
arch=(x86_64 i686 pentium4 arm armv6h armv7h aarch64)
url="http://basilisk.cebix.net"
license=(GPL)
depends=(gtk2 sdl vde2)
makedepends=(git)
provides=("basiliskii")
conflicts=(basiliskii)
source=("git+https://github.com/cebix/macemu" "configure.ac.patch")
sha256sums=('SKIP'
            'faac6d18704848574a4a5496d76ff44bf8bba6fb6a89524a8730865d3517334a')

pkgver() {
  cd macemu
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  patch --forward --strip=1 --input="${srcdir}/configure.ac.patch"
}

build() {
  cd macemu/BasiliskII/src/Unix
  ./autogen.sh \
    --prefix=/usr \
    --enable-sdl-video \
    --enable-sdl-audio \
    --enable-jit-compiler \
    --with-bincue \
    --with-vdeplug

  make -j1
}

package() {
  cd macemu/BasiliskII/src/Unix
  make DESTDIR="${pkgdir}" install
}