ColdFusion Query Transformation

queryToArray

/**
* @hint Returns reasonable array of objects from a cfquery
*/
public function queryToArray(
	required query	query,
			 string	excludeColumns = ""
){

	if (server.coldfusion.productName == "ColdFusion Server") {
		local.columns = arguments.query.getMetaData().getColumnLabels();
	} else if (server.coldfusion.productName == "Lucee") {
		local.columns = arguments.query.getColumnNames();
	} else {
		local.columns = [];
	}

	local.response = arrayNew(1);

	for (local.rowIndex=1; local.rowIndex<=arguments.query.recordCount; local.rowIndex++) {
		local.response[local.rowIndex] = structNew();

		for (local.columnIndex=1; local.columnIndex<=arrayLen(local.columns); local.columnIndex++) {
			local.columnName = local.columns[local.columnIndex];

			if(local.columnName != "" && (arguments.excludeColumns == "" || !listFindNoCase(arguments.excludeColumns, local.columnName))) {
				local.response[local.rowIndex][local.columnName] = arguments.query[local.columnName][local.rowIndex];
			}
		}
	}

	return local.response;
}

queryToStruct

/**
* @hint Returns reasonable objects from a cfquery single row
*/
public function queryToStruct(
	required query	query,
			 string	excludeColumns = "",
			 numeric row = 1
){

	if (server.coldfusion.productName == "ColdFusion Server") {
		local.columns = arguments.query.getMetaData().getColumnLabels();
	} else if (server.coldfusion.productName == "Lucee") {
		local.columns = arguments.query.getColumnNames();
	} else {
		local.columns = [];
	}

	for (local.columnIndex=1; local.columnIndex<=arrayLen(local.columns); local.columnIndex++) {
		local.columnName = local.columns[local.columnIndex];

		if(arguments.excludeColumns == "" || !listFindNoCase(arguments.excludeColumns, local.columnName)) {
			local.response[local.columnName] = arguments.query[local.columnName][arguments.row];
		}
	}

	return local.response;
}