TeamViewer PKGBUILD

.SRCINFO

pkgbase = teamviewer
	pkgdesc = All-In-One Software for Remote Support and Online Meetings
	pkgver = 12.0.71510
	pkgrel = 7
	url = http://www.teamviewer.com
	install = teamviewer.install
	arch = i686
	arch = x86_64
	license = custom
	depends = fontconfig
	depends = libpng12
	depends = libsm
	depends = libxinerama
	depends = libxrender
	depends = libjpeg6-turbo
	depends = libxtst
	provides = teamviewer
	conflicts = teamviewer-beta
	options = !strip
	source = teamviewer.install
	sha256sums = 0f7415e50d4a5ec5172027a7897678f640e3ea474162c6f2e3496ffd70368154
	source_i686 = https://download.teamviewer.com/download/version_12x/teamviewer_12.0.71510_i386.deb
	sha256sums_i686 = 172f68c05f29657bcf312b9e3fd8b77027bdf82bd969da9dd7ffcc7eb3605838
	source_x86_64 = https://download.teamviewer.com/download/version_12x/teamviewer_12.0.71510_amd64.deb
	sha256sums_x86_64 = 4c996e94f89a65097e667a2b3b6bff338a3dab914fcdce2cc555a66ed78d3a5c

pkgname = teamviewer

PKGBUILD

# Maintainer: Alex Taber <aft dot pokemon at gmail dot com>
# Contributor: Konstantin Gizdov <arch at kge dot pw>

pkgname=teamviewer
pkgver=12.0.71510
pkgrel=7
pkgdesc='All-In-One Software for Remote Support and Online Meetings'
arch=('i686' 'x86_64')
url='http://www.teamviewer.com'
license=('custom')
options=('!strip')
provides=('teamviewer')
conflicts=('teamviewer-beta')
depends=(
         'fontconfig'
         'libpng12'
         'libsm'
         'libxinerama'
         'libxrender'
         'libjpeg6-turbo'
         'libxtst')
install=teamviewer.install
source=('teamviewer.install')
source_i686=("https://download.teamviewer.com/download/version_${pkgver%%.*}x/teamviewer_${pkgver}_i386.deb")
source_x86_64=("https://download.teamviewer.com/download/version_${pkgver%%.*}x/teamviewer_${pkgver}_amd64.deb")
sha256sums=('8c00217ab16949291189bfd029cd5ae60a4774896939c37387fb16deb3126b11')
sha256sums_i686=('172f68c05f29657bcf312b9e3fd8b77027bdf82bd969da9dd7ffcc7eb3605838')
sha256sums_x86_64=('4c996e94f89a65097e667a2b3b6bff338a3dab914fcdce2cc555a66ed78d3a5c')
prepare() {
    warning "If the install fails, you need to uninstall previous major version of Teamviewer"
    tar -xf data.tar.bz2
}

package() {
    # Install
    warning "If the install fails, you need to uninstall previous major version of Teamviewer"
    cp -dr --no-preserve=ownership {etc,opt,usr,var} "${pkgdir}"/

    # Additional files
    rm "${pkgdir}"/opt/teamviewer/tv_bin/xdg-utils/xdg-email
    install -D -m0644 "${pkgdir}"/opt/teamviewer/tv_bin/script/teamviewerd.service \
        "${pkgdir}"/usr/lib/systemd/system/teamviewerd.service
    install -d -m0755 "${pkgdir}"/usr/{share/applications,share/licenses/teamviewer}
    ln -s /opt/teamviewer/License.txt \
        "${pkgdir}"/usr/share/licenses/teamviewer/LICENSE
}

teamviewer.install

post_install() {
    echo "The Teamviewer daemon must be running for Teamviewer to work."
    echo "Execute 'sudo systemctl enable teamviewerd' in a terminal."
}

post_upgrade() {
    post_install
}

post_remove() {
    rm -rf /opt/teamviewer
}

# vim: ts=2 sw=2 et: