Generating Dependencies for different build variants.

generate_dependencies.gradle

/**
 * Generates a text file containing dependencies for different build variants
 * and saves them into the respective variant asset folder.
 * Also deletes files on clean.
 *
 * Can be safely used with <code>org.gradle.unsafe.configuration-cache=true</code>
 */
android.applicationVariants.all { variant ->

    def name = variant.name
    def nameCapitalized = name.capitalize()

    preBuild.dependsOn tasks.register("list${nameCapitalized}Dependencies") {

        outputs.file(project.rootProject.file("app/src/$name/assets/dependencies.txt"))

        def dependencies = configurations
                .getByName("${name}RuntimeClasspath")
                .getResolvedConfiguration()
                .getFirstLevelModuleDependencies()
                .collect {
                    "${it.moduleGroup}:${it.moduleName}:${it.moduleVersion}\n"
                }
                .sort()

        doLast {

            description = "Generate ${outputs.files.singleFile}"
            println(description)

            dependencies.each {
                outputs.files.singleFile.append(it)
            }
        }
    }

    clean {
        delete project.rootProject.file("app/src/$name/assets/dependencies.txt")
    }
}