Interactively execute Adonisjs command

adonis.el

(defun execute-adonis-command()
  "Interactively execute adonis command in projectile root"
  (interactive)
  (projectile-with-default-dir
      (projectile-acquire-root)
    (let* ((commands-string (shell-command-to-string "node --no-warnings ace list --json"))
           (commands-json (json-parse-string commands-string :object-type 'alist))
           (commands-names (cl-loop for entry across commands-json
                                    collect (let ((description (let-alist entry .description))
                                                  (name (let-alist entry .commandName)))
                                              (list name description))))
           (command (consult--read
                     commands-names
                     :prompt "Ace command: "
                     :require-match t
                     :category 'ace-command
                     :annotate
                     (lambda (cand)
                       (format "   %s" (cadr (seq-find (lambda (item) (s-equals-p (car item) cand)) commands-names))))))
           (help-string (shell-command-to-string (concat "node --no-warnings ace " command " --help")))
           (full-command (read-string (s-trim-left (concat help-string "\n")) (concat command " "))))
      (projectile-run-shell-command-in-root (concat "node --no-warnings ace " full-command)))))