https://github.com/jaredlll08/CraftTweaker/issues/430

GH430.zs

import crafttweaker.data.IData;
import crafttweaker.item.IItemStack;

val goldBlock=<minecraft:gold_block>;

val sideItems = {
	efficiency: <minecraft:potion>.withTag({Potion: "minecraft:strong_swiftness"}),
	unbreaking: <minecraft:potion>.withTag({Potion: "minecraft:strong_strength"})
} as IItemStack[string];

val topItems = {
	efficiency: <minecraft:potion>.withTag({Potion: "minecraft:strong_swiftness"}),
	unbreaking: <minecraft:potion>.withTag({Potion: "minecraft:strong_strength"})
} as IItemStack[string];

val baseMaxLevels = {
	efficiency: 5,
	unbreaking: 3
} as int[string];

val enchantIDs = {
	efficiency: 32,
	unbreaking: 34
} as int[string];

val booksToMake = ["efficiency", "unbreaking"] as string[];

for book in booksToMake {
	var enchantID = enchantIDs[book] + 0;
	var baseMaxLevel = baseMaxLevels[book];
	var sideItem = sideItems[book];
	var topItem = topItems[book];

	for fromLevel in (baseMaxLevel .. 10) {
		var toLevel = fromLevel + 1;

		var fromTag as IData = {StoredEnchantments: [{lvl: fromLevel, id: enchantID}]};
		var toTag as IData = {StoredEnchantments: [{lvl: toLevel, id: enchantID}]};

		recipes.addShaped(book ~ fromLevel ~ "_" ~ toLevel,
			<minecraft:enchanted_book>.withTag(toTag),
			[
				[null, topItem, null],
				[sideItem, <minecraft:enchanted_book>.withTag(fromTag), sideItem],
				[null, goldBlock, null]
			]
		);

		mods.jei.JEI.addItem(<minecraft:enchanted_book>.withTag(toTag));
	}
}

GH430_alt.zs

import crafttweaker.data.IData;
import crafttweaker.item.IItemStack;

val goldBlock=<minecraft:gold_block>;

val sideItems = {
	efficiency: <minecraft:potion>.withTag({Potion: "minecraft:strong_swiftness"}),
	unbreaking: <minecraft:potion>.withTag({Potion: "minecraft:strong_strength"})
} as IItemStack[string];

val topItems = {
	efficiency: <minecraft:potion>.withTag({Potion: "minecraft:strong_swiftness"}),
	unbreaking: <minecraft:potion>.withTag({Potion: "minecraft:strong_strength"})
} as IItemStack[string];

val baseMaxLevels = {
	efficiency: 5,
	unbreaking: 3
} as IData[string];

val enchantIDs = {
	efficiency: 32,
	unbreaking: 34
} as IData[string];

val booksToMake = ["efficiency", "unbreaking"] as string[];

for book in booksToMake {
	var enchantID = enchantIDs[book];
	var baseMaxLevel = baseMaxLevels[book].asInt();
	var sideItem = sideItems[book];
	var topItem = topItems[book];

	for fromLevel in baseMaxLevel .. 10 {
		var toLevel = fromLevel + 1;

		var fromTag as IData = {StoredEnchantments: [{lvl: fromLevel, id: enchantID}]};
		var toTag as IData = {StoredEnchantments: [{lvl: toLevel, id: enchantID}]};

		recipes.addShaped("alt" ~ book ~ fromLevel ~ "_" ~ toLevel,
			<minecraft:enchanted_book>.withTag(toTag),
			[
				[null, topItem, null],
				[sideItem, <minecraft:enchanted_book>.withTag(fromTag), sideItem],
				[null, goldBlock, null]
			]
		);

		mods.jei.JEI.addItem(<minecraft:enchanted_book>.withTag(toTag));
	}
}