Disable terminal echoing in SBCL (e.g. for password prompts)

example.lisp

(defun prompt-for-password ()
  (format t "Password: ")
  (force-output)
  (with-echoing-disabled
    (prog1
        (read-line)
      (terpri))))

(format t "got ~S~%" (prompt-for-password))

run.sh

sbcl --noinform --load with-echoing-disabled.lisp --load example.lisp --quit

with-echoing-disabled.lisp

(require 'sb-posix)

(defun invoke-with-echoing-disabled (thunk)
  (let ((fd (sb-sys:fd-stream-fd sb-sys:*stdout*)))
    (if (zerop (sb-unix:unix-isatty fd))
        (funcall thunk)
        (let ((termios (sb-posix:tcgetattr fd)))
          (setf (sb-posix:termios-lflag termios)
                (logand (sb-posix:termios-lflag termios)
                        (lognot sb-posix:echo)))
          (sb-posix:tcsetattr fd sb-posix:tcsaflush termios)
          (unwind-protect
               (funcall thunk)
            (setf (sb-posix:termios-lflag termios)
                  (logior (sb-posix:termios-lflag termios)
                          sb-posix:echo))
            (sb-posix:tcsetattr fd sb-posix:tcsaflush termios))))))

(defmacro with-echoing-disabled (&body body)
  `(invoke-with-echoing-disabled (lambda () ,@body)))