sed script for automated metrical analysis of latin texts

skandieren.sed

s/\(.*\)/\L\1/g
s/[^a-z ]//g
s/\s\+/ /g
s/^ //g

# i initiale
s/\bi\([aeouy]\)/j\1/g

# synizesis / synalloephe
s/\([aeiou]m\?\) est/\1st/g
s/\([aeiou]m\?\) h\?\([aeiou]\)/\2/g
s/ae/æ/g

# syllabae positione longae
s/a\([xz]\)/ā\1/g
s/e\([xz]\)/ē\1/g
s/i\([xz]\)/ī\1/g
s/o\([xz]\)/ō\1/g
s/u\([xz]\)/ū\1/g

s/a\(\([bcdfgjlmnpqrstvxz]\{2,\}\)\|\([bcdfgjlmnpqrstvxz] [bcdfgjlmnpqrstvxz]\)\)/ā\1/g
s/e\(\([bcdfgjlmnpqrstvxz]\{2,\}\)\|\([bcdfgjlmnpqrstvxz] [bcdfgjlmnpqrstvxz]\)\)/ē\1/g
s/i\(\([bcdfgjlmnpqrstvxz]\{2,\}\)\|\([bcdfgjlmnpqrstvxz] [bcdfgjlmnpqrstvxz]\)\)/ī\1/g
s/o\(\([bcdfgjlmnpqrstvxz]\{2,\}\)\|\([bcdfgjlmnpqrstvxz] [bcdfgjlmnpqrstvxz]\)\)/ō\1/g
s/u\(\([bcdfgjlmnpqrstvxz]\{2,\}\)\|\([bcdfgjlmnpqrstvxz] [bcdfgjlmnpqrstvxz]\)\)/ū\1/g

# muta cum liquida
s/ā\([ptcbdg][rl]\)/a\1/g
s/ē\([ptcbdg][rl]\)/e\1/g
s/ī\([ptcbdg][rl]\)/i\1/g
s/ō\([ptcbdg][rl]\)/o\1/g
s/ū\([ptcbdg][rl]\)/u\1/g

# suffixa longa
s/i\(que\)\?\b/ī\1/g
s/o\(que\)\?\b/ō\1/g
s/es\(que\)\?\b/ēs\1/g
s/as\(que\)\?\b/ās\1/g
s/os\(que\)\?\b/ōs\1/g

# initium versi
s/^\([bcdfghjlmnpqrstvxz]*\)a/\1ā/g
s/^\([bcdfghjlmnpqrstvxz]*\)e/\1ē/g
s/^\([bcdfghjlmnpqrstvxz]*\)i/\1ī/g
s/^\([bcdfghjlmnpqrstvxz]*\)o/\1ō/g
s/^\([bcdfghjlmnpqrstvxz]*\)u/\1ū/g

# vocalis ante vocalem corripitur
s/ā\([āēīōūæ]\)/a\1/g
s/ē\([āēīōūæ]\)/e\1/g
s/ī\([āēīōūæ]\)/i\1/g
s/ō\([āēīōūæ]\)/o\1/g
s/ū\([āēīōūæ]\)/u\1/g