for 3ds-libxmp

PKGBUILD

# Maintainer: Chromaryu <knight.ryu12@gmail.com>
pkgname=3ds-libxmp-git
pkgver=libxmp.4.4.1
pkgrel=1
pkgdesc="Library that supports over 90 module formats (Amiga, Atari, ..)"
arch=('any')
url="http://xmp.sourceforge.net/"
license=('GPL')
#depends=('glibc')
options=(!strip libtool staticlibs)
depends=('3ds-pkg-config' 'devkitpro-pkgbuild-helpers')
optdepends=('')
makedepends=('git')
conflicts=('3ds-libxmp')
provides=('3ds-libxmp')
source=("$pkgname"::"git+https://github.com/cmatsuoka/libxmp.git")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
        cd "$srcdir/$pkgname"
        source /opt/devkitpro/devkitarm.sh
        source /opt/devkitpro/3dsvars.sh
        autoconf
        ./configure --prefix="${PORTLIBS_PREFIX}" --host=arm-none-eabi \
                    --disable-shared --enable-static
        make
}

package() {
        cd "$srcdir/$pkgname"
        source /opt/devkitpro/devkitarm.sh
        source /opt/devkitpro/3dsvars.sh
        make DESTDIR="$pkgdir" install
}