PKGBUILDs

libcouchbase-2.4.4

# Maintainer: Gabriel Garrido <kainlite@gmail.com>
# Contributors: Lev Lybin <lev.lybin@gmail.com>, Kiswono <kiswono@gmail.com>

pkgname=libcouchbase
pkgver=2.4.4
pkgrel=1
pkgdesc="The C library provides fast access to documents in Couchbase Server 2.0."
arch=('i686' 'x86_64')
url="https://github.com/couchbase/libcouchbase"
license=('Apache')
options=('!emptydirs' '!strip')
depends=('libevent')
source=("https://github.com/couchbase/libcouchbase/archive/${pkgver}.tar.gz")
md5sums=('cfb3b46b1db2de344bd3d449d6230b3d')

build() {
  tar -xzf ${pkgver}.tar.gz -C "${srcdir}/libcouchbase-${pkgver}"
  cd "${srcdir}/libcouchbase-${pkgver}"
  cmake CMakeLists.txt 
  make || return 1
}

package() {
  cd "${srcdir}/libcouchbase-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/LICENSE "{$pkgdir}/usr/share/licenses/{$pkgname}/LICENSE"
}

postgresql-testing-9.4rc1

# Maintainer: Marti Raudsepp <marti@juffo.org>
# Contributor: Dan McGee <dan@archlinux.org>, Kiswono <kiswono@gmail.com>

pkgname=postgresql-testing
pkgver=9.4rc1
pkgrel=1
_majorver=9.4
pkgdesc="Beta and RC version of the PostgreSQL database (includes both server and libs)"
arch=('i686' 'x86_64')
url="https://wiki.postgresql.org/wiki/HowToBetaTest"
license=('custom:PostgreSQL')
backup=('etc/pam.d/postgresql' 'etc/logrotate.d/postgresql')
options=('!emptydirs' '!strip') # to facilitate debugging of testing builds
depends=('libxml2' 'readline>=6.0' 'openssl>=1.0.0')
makedepends=('python2' 'perl')
optdepends=('python2: for PL/Python support'
            'perl: for PL/Perl support')
conflicts=('postgresql-libs' 'postgresql' 'postgresql-testing')
provides=("postgresql-libs=$pkgver" "postgresql=$pkgver")
source=("http://ftp.postgresql.org/pub/source/v$pkgver/postgresql-$pkgver.tar.bz2"
        postgresql-run-socket.patch
        postgresql.pam postgresql.logrotate
        postgresql.service postgresql.tmpfiles.conf postgresql-check-db-dir)
install=postgresql.install

build() {
  cd $srcdir/postgresql-$pkgver

  patch -Np1 < ../postgresql-run-socket.patch
  ./configure --prefix=/usr \
  --mandir=/usr/share/man \
  --datadir=/usr/share/postgresql \
  --sysconfdir=/etc \
  --with-libxml \
  --with-openssl \
  --with-perl \
  --with-python PYTHON=/usr/bin/python2 \
  --with-pam \
  --with-system-tzdata=/usr/share/zoneinfo \
  --enable-nls \
  --enable-thread-safety
  #--with-krb5 \
  #--with-tcl \

  make
  make -C contrib
}

package() {
  cd $srcdir/postgresql-$pkgver

  # install
  make DESTDIR="${pkgdir}" install
  make -C contrib DESTDIR="${pkgdir}" install

  # install license
  install -D -m644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgbase}/LICENSE"

  install -D -m644 "${srcdir}/postgresql.tmpfiles.conf" \
    "${pkgdir}/usr/lib/tmpfiles.d/postgresql.conf"
  install -D -m644 "${srcdir}/postgresql.service" \
    "${pkgdir}/usr/lib/systemd/system/postgresql.service"
  install -D -m755 "${srcdir}/postgresql-check-db-dir" \
    "${pkgdir}/usr/bin/postgresql-check-db-dir"
  install -D -m644 "${srcdir}/postgresql.pam" \
    "${pkgdir}/etc/pam.d/postgresql"
  install -D -m644 "${srcdir}/postgresql.logrotate" \
    "${pkgdir}/etc/logrotate.d/postgresql"
}
md5sums=('f5a880a31db0cf8dc8282895e2e689d7'
         '75c579eed03ffb2312631f0b649175b4'
         '96f82c38f3f540b53f3e5144900acf17'
         'd28e443f9f65a5712c52018b84e27137'
         '89b48774b0dae7c37fbb0e907c3c1db8'
         '1c5a1f99e8e93776c593c468e2612985'
         'ba9b7d804500dffc095eac78c4a2a00f')

v8-3.21.17

# $Id$
# Current Maintainer: Kiswono Prayogo <kiswono@gmail.com>
# Original maintainer: Kaiting Chen <kaitocracy@gmail.com>
# Original contributor: tocer <tocer.deng@gmail.com>

pkgname=v8-3.21
pkgver=3.21.17
pkgrel=1
pkgdesc='A fast and modern javascript engine (old 3.21 version required for couchbase)'
arch=('i686' 'x86_64')
url='http://code.google.com/p/v8'
license=('BSD')
depends=('gcc-libs' 'readline')
makedepends=('subversion' 'python2')
source=(https://github.com/v8/v8-git-mirror/archive/$pkgver.tar.gz)
sha256sums=('7a87fefba8565dfe9899b1034301bad062239a5a7eaa32b9b8f0b0490295c1a2')
provides=('v8')
conflicts=('v8')

[[ "$CARCH" = 'i686' ]]   && ARCH=ia32
[[ "$CARCH" = 'x86_64' ]] && ARCH=x64

build() {
  cd v8-git-mirror-$pkgver

  # Fetch gyp
  make dependencies

  # The world isn't ready for python2
  export PYTHON=python2
  find build/ test/ tools/ src/ -type f \
    -exec sed -e 's_^#!/usr/bin/env python$_&2_' \
              -e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
              -e 's_^#!/usr/bin/python$_&2_' \
              -e "s_'python'_'python2'_" -i {} \;
  sed -i 's/python /python2 /' Makefile

  # -Werror causes errors with newer versions of GCC
  sed -i 's/-Werror//' build/standalone.gypi build/toolchain.gypi

  make $ARCH.release library=shared console=readline
}

package() {
  cd v8-git-mirror-$pkgver

  install -Dm755 out/$ARCH.release/d8 $pkgdir/usr/bin/d8
  install -Dm755 out/$ARCH.release/lib.target/libv8.so $pkgdir/usr/lib/libv8.so

  install -d $pkgdir/usr/include
  install -Dm644 include/*.h $pkgdir/usr/include

  install -d $pkgdir/usr/share/licenses/v8
  install -m644 LICENSE* ${pkgdir}/usr/share/licenses/v8
}