PKGBUILD for python-pyephem 4.1.5-3 that depends on Python 3.12

PKGBUILD

# Maintainer: Lukasz Pozarlik <lpozarlik at gmail dot com>
# Contributor: Masutu Subric <masutu dot arch at gmail dot com>
# Contributor: Michal Marek <reqamst at gmail dot com>
# Contributor: Klaus Alexander Seistrup <klaus at seistrup dot dk>

pkgname=('python-pyephem')
pkgver=4.1.5
pkgrel=3
pkgdesc='PyEphem provides scientific-grade astronomical computations'
arch=('aarch64' 'i686' 'x86_64')
url='http://rhodesmill.org/pyephem/'
license=('MIT')  # SPDX-License-Identifier: MIT
makedepends=('python-build' 'python-installer' 'python-wheel')
depends=('glibc' 'python>=3.12')
options=('lto' '!emptydirs')
source=(
  "https://files.pythonhosted.org/packages/source/e/ephem/ephem-$pkgver.tar.gz"
)
sha256sums=('0c64a8aa401574c75942045b9af70d1656e14c5366151c0cbb400cbeedc2362a')

build() {
  cd "$srcdir/ephem-$pkgver"

  python -m build --wheel --no-isolation
}

package() {
  cd "$srcdir/ephem-$pkgver"

  python -m installer --destdir="$pkgdir" dist/*.whl

  install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname/" \
    README.rst
  install -vDm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" \
    LICENSE
}

# eof