A script to create the Lambdacats sticker pack

lambdacats.hs

#!/usr/bin/env cabal
{- cabal:
build-depends: base, scalpel, process, async, filepath, directory
ghc-options: -threaded -rtsopts -with-rtsopts=-N
-}
{-# LANGUAGE OverloadedStrings #-}

module Main where

import Control.Monad
import Text.HTML.Scalpel
import System.Directory
import Control.Concurrent.Async
import System.Process
import System.FilePath.Posix

main :: IO ()
main = do
  let url = "https://lambdacats.github.io/"
      basedir = "/tmp/lambdacats"
  Just imgRelLinks <- scrapeURL url (attrs "src" "img")
  createDirectoryIfMissing True basedir
  let imgLinks = map (url ++) imgRelLinks
      fileNames = map takeFileName imgRelLinks
      destPaths = map (basedir </>) fileNames
  mapConcurrently_ download (zip imgLinks destPaths)
  mapConcurrently_ makeSticker destPaths

download :: (URL, FilePath) -> IO ()
download (url, dest) = callProcess "wget" [url, "-O", dest]

makeSticker :: FilePath -> IO ()
makeSticker inputPath = do
  let png = replaceExtension inputPath "png"
      outputPath = replaceExtension inputPath "webp"
  callProcess "convert" [inputPath, "-resize", "512x512", png]
  callProcess "cwebp" [png, "-o", outputPath]