Working KiCAD interactive drag+shove routing build

kicad.install

pkgname=kicad-git

post_install() {
  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
  update-mime-database usr/share/mime > /dev/null
  update-desktop-database -q
}

post_upgrade() {
  post_install $1
}

post_remove() {
  post_install $1
}

PKGBUILD

# Maintainer: Samuel Ace Winchenbach <swinchen at gmail dot com>
# Contriubuor: Kyle Keen <keenerd@gmail.com>
# Contributor: Marq Schneider <queueRAM@gmail.com>

pkgname=kicad-git
pkgver=r6331.8023c7a
pkgrel=9
pkgdesc="Electronic schematic and printed circuit board (PCB) design tools"
arch=('i686' 'x86_64')
url="http://kicad-pcb.org/"
license=('GPL')
depends=('glew' 'wxgtk' 'desktop-file-utils' 'boost-libs' 'python' 'glm' 'curl')
makedepends=('cmake' 'git' 'zlib' 'mesa' 'boost')
optdepends=('kicad-library: for footprints')
conflicts=('kicad' 'kicad-bzr')
provides=('kicad')
install=kicad.install
source=("${pkgname}"'::git+git://git.launchpad.net/kicad#branch=4.0')
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${pkgname}"
  printf "r%s.%s" "$(git rev-list HEAD --count --first-parent)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${srcdir}/${pkgname}"
  mkdir -p build/Debug
  cd build/Debug
  # -DKICAD_SCRIPTING=ON -DKICAD_SCRIPTING_MODULES=ON ?
  # -DKICAD_SCRIPTING_WXPYTHON=ON ?
  cmake ../.. -DCMAKE_BUILD_TYPE=Debug \
              -DCMAKE_INSTALL_PREFIX=/usr \
              -DBUILD_GITHUB_PLUGIN=OFF
  make #-j1
}

package() {
  cd "${srcdir}/${pkgname}"
  cd build/Debug
  make DESTDIR="${pkgdir}" install
}