Apple Keynote: export presenter notes

keynote.scpt

-- HOWTO:
-- after saving it, open with Script Editor (default) and run it

-- PREREQUISITES:
-- make sure your Keynote presentation is open in the background

set presenterNotes to ""
set slideNumber to 1

tell application "Keynote"
	activate
	tell front document
		set thePresentationName to name
		
		repeat with sc from 1 to the count of slides
			tell slide sc
				if not (the presenter notes) = "" and not (skipped) then
					set presenterNotes to presenterNotes & "# P" & slideNumber & return
					set presenterNotes to presenterNotes & the presenter notes & return & return
					set slideNumber to slideNumber + 1
				end if
			end tell
		end repeat
	end tell
end tell

set userName to system attribute "USER"
set filePath to "/Users/" & userName & "/Desktop/notes-" & thePresentationName & ".md"
do shell script "echo " & quoted form of presenterNotes & " > " & quoted form of filePath

-- based on http://apple.stackexchange.com/questions/136118/how-to-print-full-presenter-notes-without-slides-in-keynote

This is awesome!
Thanks a lot!