Names substitution in declaration templates (TH + SYB)

TH+SYB_substNames.hs

{-# LANGUAGE TemplateHaskell #-}

import Language.Haskell.TH
import Language.Haskell.TH.Lib hiding (rename)
import Control.Monad           (liftM)
import Data.List               (lookup)
import Data.Generics.Aliases   (mkT)
import Data.Generics.Schemes   (everywhere)

----------------------------------------------------------------

type NamesMap = [(String, String)]

rename :: NamesMap -> (Name -> Name)
rename namesMap = \ oldName ->
    case lookup (show oldName) namesMap of
         Nothing  -> oldName
         Just new -> mkName new

renameDecs :: NamesMap -> Q [Dec] -> Q [Dec]
renameDecs namesMap = liftM $ everywhere $ mkT $ rename namesMap

----------------------------------------------------------------

fooTemplate :: String -> Int -> Int -> String -> Q [Dec]
fooTemplate name y z blah = renameDecs [("foo", name)]
    [d| foo :: Num a => a -> a -> String
        foo x 1 = show $ x + y
        foo x 2 = show $ x - z
        foo x _ = show x ++ blah
      |]