Find anagrams for a given word in a dictionary.

anagram.clj

; ----------------------------------------------------------
; Find anagrams for a given word in a dictionary
;   @authors  Gustavo Leite, Bruno Souza
;   @date     October 28th 2015
;
; Usage: (pretty-anagram "algo" dictionary)
;   => Anagrams for algo: galo, gola, lago, olga
;
; To import it in core.clj, add the statement:
;   (:require [lab.anagram :refer :all])
; in the ns definition.
; ----------------------------------------------------------
(ns lab.anagram
  (:require [clojure.string :as str]
            [lab.acentos :refer [remove-accents]]))

(def dictionary 
  (str/split-lines (slurp "./resources/substantivos.txt")))

(defn prepare-word [word]
  (apply str (-> word .toLowerCase remove-accents sort)))

(defn anagram [word dic]
  (let [sorted (prepare-word word)
        fdic   (filter #(= (count word) (count %)) dic)
        pdic   (map prepare-word fdic)
        pair   (map vector fdic pdic)]
    (->> (filter #(= sorted (get % 1)) pair)
         (map #(get % 0)))))

(defn pretty-anagram [word dic]
  (print (str "Anagrams for " word ": " (str/join ", " (anagram word dic)) "\n")))