https://qiita.com/SaitoAtsushi/items/d20199bfdd2d09211a5d

binding.scm

#!r6rs
(library (binding)
  (export bound?)
  (import
    (for (only (rnrs base) eq? list not quote lambda eqv? unquote quasiquote) expand)
    (for (only (rnrs base) define-syntax) run)
    (for (only (rnrs lists) exists) expand)
    (for (only (rnrs syntax-case)
               quasisyntax unsyntax
               syntax-case syntax free-identifier=? syntax->datum datum->syntax)
      expand)
    (for (only (rnrs eval) eval environment) expand))

  (define-syntax bound?
    (lambda(ctx)
      (syntax-case ctx ()
        ((_ id)
         (exists (lambda(x)(free-identifier=? #'id x))
                 (list #'syntax #'quote #'syntax->datum #'datum->syntax))
         ;; id: bound as syntax, quote, syntax->datum, datum->syntax, or aliases to them
         #t)
        ((_ id)
         (free-identifier=?
          (eval `(datum->syntax #'k ',(syntax->datum #'id))
                (environment '(only (rnrs)
                                    datum->syntax
                                    syntax->datum
                                    syntax
                                    quote
                                    )))
          #'id)
         ;; id: unbound (except for datum->syntax, syntax, syntax, and quote)
         #f)
        ((_ id)
         (exists (lambda (x) (eq? (syntax->datum #'id) x))
                 '(datum->syntax syntax->datum syntax quote))
         ;; id: unbound datum->syntax, syntax->datum, syntax, or quote
         #f)
        ((_ id)
         ;; otherwise, id should be bound
         #t)
        )))
  )

m.scm

#!r6rs
(import (except (rnrs) syntax datum->syntax)
        (rename (only (rnrs) syntax)
                (syntax stx))
        (binding))

(define x 0)

(define-syntax test-bound?
  (syntax-rules ()
    ((_ ids ...)
     (begin
       (begin (display `(bound? ,'ids))
              (display "\t;; => ")
              (display (bound? ids))
              (newline))
       ...))))

(test-bound? stx syntax define quote datum->syntax t x)

output.chez.scm

;; output of chez --program m.scm
(bound? stx)    ;; => #t
(bound? syntax) ;; => #f
(bound? define) ;; => #t
(bound? quote)  ;; => #t
(bound? datum->syntax)  ;; => #f
(bound? t)      ;; => #f
(bound? x)      ;; => #t

output.racket.scm

;; output of plt-r6rs m.scm
;; setup: plt-r6rs --install binding.scm
{bound? stx}    ;; => #t
{bound? syntax} ;; => #t
{bound? define} ;; => #t
{bound? quote}  ;; => #f
{bound? datum->syntax}  ;; => #t
{bound? t}      ;; => #f
{bound? x}      ;; => #t

output.sagittarius.scm

;; output of sagittarius -L. m.scm
(bound? stx)    ;; => #t
(bound? syntax) ;; => #t
(bound? define) ;; => #t
(bound? quote)  ;; => #t
(bound? datum->syntax)  ;; => #f
(bound? t)      ;; => #f
(bound? x)      ;; => #t