list_examples.c3

import std::io;
import std::collections::list;

define DoubleList = List<double>;

fn double test_list_on_heap(int len)
{
	DoubleList list;   // By default will allocate on the heap
	defer list.free(); // Free at end
	for (int i = 0; i < len; i++)
	{
		list.push(i + 1.0);
	}
	double sum = 0;
	foreach (d : list) sum += d;
	return sum;
}

fn double test_list_on_temp_allocator(int len)
{
	DoubleList list;
	@pool()
	{
		list.temp_init(); // Temp init
		for (int i = 0; i < len; i++)
		{
			list.push(i + 1.0);
		}
		double sum = 0;
		foreach (d : list) sum += d;
		// No need to free explicitly
		return sum;
	};
}

fn double test_array_on_heap(int len)
{
	double[] arr = mem::alloc_array(double, len);
	defer mem::free(arr); // Free at end.
	for (int i = 0; i < len; i++)
	{
		arr[i] = i + 1.0;
	}
	double sum = 0;
	foreach (d : arr) sum += d;
	return sum;
}

fn double test_array_on_temp_allocator(int len)
{
	@pool()
	{
		double[] arr = array::talloc_array(double, len); // Released when exiting `pool()`
		for (int i = 0; i < len; i++)
		{
			arr[i] = i + 1.0;
		}
		double sum = 0;
		foreach (d : arr) sum += d;
		return sum;
	};
}

fn void main()
{
	io::printfn("Sum 1-10: %d", test_list_on_heap(10));
	io::printfn("Sum 1-10: %d", test_list_on_temp_allocator(10));
	io::printfn("Sum 1-10: %d", test_array_on_heap(10));
	io::printfn("Sum 1-10: %d", test_array_on_temp_allocator(10));
}