local-expansion.rkt

#lang racket

(require (for-syntax syntax/kerncase)
         syntax/parse/define)

(define-simple-macro (m1 e:expr)
  #:with x (local-expand #'e 'expression (kernel-form-identifier-list))
  (quote-syntax x))

(define-simple-macro (m1.1 e:expr)
  #:with x (local-expand #'e 'expression (list #'begin))
  (quote-syntax x))

(define-simple-macro (m1.2 e:expr)
  #:with x (local-expand #'e 'expression (list #'#%datum #'#%app #'#%top))
  (quote-syntax x))

(define-simple-macro (m2 e:expr)
  #:with x (local-expand #'e 'expression #f)
  (quote-syntax x))

(define-simple-macro (m3 e:expr)
  #:with x (local-expand #'e 'expression '())
  (quote-syntax x))

(define-simple-macro (#%datum  . _)
  (quote datum))

(define-simple-macro (#%app . _)
  (quote app))

(define-simple-macro (#%top . _)
  (quote top))

(m1 #f)    ; => 'datum
(m1.1 #f)  ; => 'datum
(m1.2 #f)  ; => #f
(m2 #f)    ; => #f
(m3 #f)    ; => 'datum

(#%plain-app newline)

(m1 (+))    ; => 'app
(m1.1 (+))  ; => 'app
(m1.2 (+))  ; => (+)
(m2 (+))    ; => (+)
(m3 (+))    ; => 'app

(#%plain-app newline)

(m1 unbound)    ; => 'top
(m1.1 unbound)  ; => 'top
(m1.2 unbound)  ; => unbound
(m2 unbound)    ; => unbound
(m3 unbound)    ; => 'top