OCR Service Apex Class

gistfile1.txt

public without sharing class OCRService {
    public void runOCRRollups(List<OpportunityContactRoleChangeEvent> changeEvents) {
        Set<String> oppContactRoleIds = new Set<String>();

        for (OpportunityContactRoleChangeEvent evt : changeEvents) {
            EventBus.ChangeEventHeader header = evt.ChangeEventHeader;

            oppContactRoleIds.addAll(new Set<String>(header.recordids));
        }

        // Doesn't fetch deleted Opportunity Contact Roles because
        // they're not returned from the database despite the "ALL ROWS"
        // being added. It's as if they're "Purged" instead of soft deleted.
        // Use scheduled DLRS to compensate.
        List<OpportunityContactRole> oppContactRoles =
        [SELECT Id,
                OpportunityId,
                ContactId
           FROM OpportunityContactRole
          WHERE Id in :oppContactRoleIds
         ALL ROWS];
        
        // Runs the Developer Opportunity Contact Role Declarative Lookup Rollup Summaries
        List<SObject> parentRecordsToUpdate = dlrs.RollupService.rollup(oppContactRoles);
        
        if (parentRecordsToUpdate.size() > 0) {
            update parentRecordsToUpdate;
        }
    }
}