f# version that does not work

type A = { thing: int }
type B = { label: string }

let show (a:A) = 
	sprintf "%A" a

let show (b:B) =
	sprintf "%A" b

{ thing = 98 } |> show |> Console.WriteLine

f# version using interfaces

type IShow =
	abstract member show : unit -> string

type A = 
	{ thing: int }
	interface IShow with
		member this.show() = sprintf "%A" this
		
type B = 
	{ label: string }
	interface IShow with
		member this.show() = sprintf "%A" this
		
let show (x:IShow) =
	x.show()
	
{ thing = 98 } |> show |> Console.WriteLine
{ label = "Car" } |> show |> Console.WriteLine

f# version with member overloading

type A = { thing: int }
type B = { label: string }

type ThingThatShows =
    static member show(x:A) = sprintf "%A" x
    static member show(x:B) = sprintf "%A" x
	
	
{ thing = 98 } |> ThingThatShows.show |> Console.WriteLine
{ label = "Car" } |> ThingThatShows.show |> Console.WriteLine

f# version with statically resolved type constraints

type A = { thing: int }
	with static member show a = sprintf "%A" a
	
type B = { label: string }
	with static member show b = sprintf "%A" b
	
let inline show (x:^t) =
	(^t: (static member show: ^t -> string) (x))
	
{ thing = 98 } |> show |> Console.WriteLine
{ label = "Car" } |> show |> Console.WriteLine

Two types implementing a type class

class Showable a where
	shw :: a -> String

data A = A String
data B = B Int

instance Showable A where
	shw (A s) = s

instance Showable B where
	shw (B i) = show i