Performance comparison of filtering atomics in list A not contained in list B

filter-time-comparison.xq

xquery version "3.1";

declare variable $local:millisecond := xs:dayTimeDuration('PT0.001S');

declare variable $local:max := 3000;
declare variable $local:reference := for-each(1 to $local:max, xs:string(?));
declare variable $local:test := for-each((3 to 400, 402 to 2900), xs:string(?));

declare function local:one () {
    let $as-map :=
        for-each($local:test, function ($k) {
            map { $k : true() }
        })
        => map:merge()

    let $filter-fun := function ($i) { not(map:contains($as-map, $i)) }

    return filter($local:reference, $filter-fun)
};

declare function local:two () {
    $local:reference[not(. = $local:test)]
};

declare function local:test ($f) {
    let $start := util:system-time()
    let $run := $f()
    let $duration := (util:system-time() - $start) div $local:millisecond
        
    return "Found " || string-join($run, ", ") || " of " || $local:max || " in " || $duration || "ms"
};

(
    "one:", local:test(local:one#0)
,
    "two:", local:test(local:two#0)
)