Qt subdirs project and setup deps between subprojects

build.txt

include( ../common.pri )

TEMPLATE = app

SOURCES += main.cpp

LIBS += -L../logic -llogic \
        -L../gui  -lgui

# Will build the final executable in the main project directory.
TARGET = ../project

common.txt

#Includes common configuration for all subdirectory .pro files.
INCLUDEPATH += . ..

TEMPLATE = lib

#remove main.cpp to prevent multiple compilation
SOURCES -= main.cpp

# The following keeps the generated files at least somewhat separate
# from the source files.
UI_DIR = uics
MOC_DIR = mocs
OBJECTS_DIR = objs

gui.txt

include( ../common.pri )

FORMS += gui.ui
HEADERS += gui.h
SOURCES += gui.cpp

logic.txt

include( ../common.pri )

HEADERS += logic.h
SOURCES += logic.cpp

project.txt

TEMPLATE = subdirs
SUBDIRS = logic \
          gui

# build must be last:
CONFIG += ordered
SUBDIRS += build

structure

project_dir/
-project.pro
-common.pri
-logic/
----logic.pro
----some logic files
-gui/
----gui.pro
----gui files
-build/
----build.pro
----main.cpp