Edited PKGBUILD for findpkg

findpkg.tmpfiles

D /var/lib/findpkg

PKGBUILD

# Maintainer: Alex Macleod <alex@macleod.io>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>

pkgname=findpkg
pkgver=1.0.0
pkgrel=2
pkgdesc="A fast command not found hook"
arch=('x86_64')
url="https://github.com/Alexendoo/findpkg"
license=('MIT')
depends=('pacman')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
        'findpkg.tmpfiles')
sha256sums=('0418c327b8211077b5fe9308bb434faa5a81d8f2f8a64032626f7404d5f310b3'
            'fc297fa1d14f4fd40282bf982f368aabd9f139792550031f0f2b289996b7b9d0')

prepare() {
	cd "$pkgname-$pkgver"
	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
	export RUSTUP_TOOLCHAIN=stable
	export CARGO_TARGET_DIR=target
	cd "$pkgname-$pkgver"
	cargo build --release --frozen --all-features
}

check() {
	cd "$pkgname-$pkgver"
	cargo test --frozen --all-features
}

package() {
	cd "$pkgname-$pkgver"
	install -D target/release/findpkg -t "$pkgdir/usr/bin/"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/findpkg/LICENSE"
	install -Dm644 "$srcdir/findpkg.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
}