PKGBUILD

# Maintainer: Gabriel Rauter <rauter.gabriel@gmail.com>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>

pkgname=pls
pkgver=1.9.3
pkgrel=2
pkgdesc='A better ls for developers'
url='https://github.com/dhruvkb/pls'
arch=('any')
license=('GPL3')
depends=(
  'python-rich'
  'python-yaml'
)
optdepends=(
  'nerd-fonts: icon support'
)
makedepends=(
  'python-poetry-core'
  'python-build'
  'python-installer'
  'python-wheel'
)

source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('eb2e93d254b03e2871f9d5872a4695328dba7540fbbe77db2a65f734af9bf390')

build() {
  cd "$pkgname-$pkgver"
  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  export PYTHONHASHSEED=0
  cd "$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir/" dist/*.whl
}

PKGBUILD.patch

diff --git a/PKGBUILD b/PKGBUILD
index a867b23..cea13c3 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,10 +1,11 @@
 # Maintainer: Gabriel Rauter <rauter.gabriel@gmail.com>
+# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
 
 pkgname=pls
 pkgver=1.9.3
-pkgrel=1
+pkgrel=2
 pkgdesc='A better ls for developers'
-url='https://pypi.org/project/pls/'
+url='https://github.com/dhruvkb/pls'
 arch=('any')
 license=('GPL3')
 depends=(
@@ -15,24 +16,22 @@ optdepends=(
   'nerd-fonts: icon support'
 )
 makedepends=(
-  'git'
-  'python-dephell'
+  'python-poetry-core'
+  'python-build'
+  'python-installer'
+  'python-wheel'
 )
 
-source=($pkgname::"git+https://github.com/dhruvkb/pls#tag=$pkgver")
-sha512sums=('SKIP')
-
-prepare() {
-  cd $pkgname
-  dephell deps convert --from pyproject.toml --to setup.py
-}
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha256sums=('eb2e93d254b03e2871f9d5872a4695328dba7540fbbe77db2a65f734af9bf390')
 
 build() {
-  cd $pkgname
-  python setup.py build
+  cd "$pkgname-$pkgver"
+  python -m build --wheel --skip-dependency-check --no-isolation
 }
 
 package() {
-  cd $pkgname
-  python setup.py install --root="$pkgdir" -O1 --skip-build
+  export PYTHONHASHSEED=0
+  cd "$pkgname-$pkgver"
+  python -m installer --destdir="$pkgdir/" dist/*.whl
 }