Batman.js controller which adds rails-style layouts to controllers

batman-layoutcontroller.coffee

class Batman.LayoutController extends Batman.Controller
  render: (options = {}) ->
    layout = options.layout ? @layout ? Batman.helpers.underscore(@get('routingKey'))

    if layout
      # Prefetch the action's view in parallel
      source = options.source || Batman.helpers.underscore(@get('routingKey') + '/' + @get('action'))
      Batman.View.store.prefetch source

      # Fetch the layout's view and apply context
      layoutView = @renderCache.viewForOptions
        viewClass: Batman.View
        context: @get('_renderContext')
        source: Batman.helpers.underscore('layouts/' + @get('routingKey'))

      # Render the layout's view into the DOM, the action into the layout
      layoutView.on 'ready', =>
        Batman.DOM.Yield.withName(options.into || @defaultRenderYield).replace layoutView.get('node')
        options.into = 'content' # TODO: Make customizable somehow
        super(options)

    else
      super(options)