Brief demo of using a platform module to constrain dependency versions

app_build.gradle.kts

dependencies {
    implementation(enforcedPlatform(project(":dependency-constraints")))
  
    implementation("org.jetbrains.kotlin:kotlin-stdlib")
    implementation("androidx.lifecycle:lifecycle-livedata-ktx")
    implementation("io.coil-kt:coil")
}

dependency-constraints_build.gradle.kts

plugins {
    id("java-platform")
    id("maven-publish")
}

javaPlatform {
    allowDependencies()
}

dependencies {
    api(enforcedPlatform("org.jetbrains.kotlin:kotlin-bom:1.4.20"))
  
    constraints {
        api("androidx.lifecycle:lifecycle-livedata-ktx:2.3.0-beta01")
        api("io.coil-kt:coil:1.0.0")
    }
}

publishing {
    publications {
        create<MavenPublication>("getBusyPlatform") {
            from(components["javaPlatform"])
        }
    }
}

settings.gradle.kts

include("dependency-constraints")

Thanks a lot for the insights :)

it disables regular dependency declarations as that is usually a bug

Doesn't this allow it back?

javaPlatform {
    allowDependencies()
}

This or BOMs themselves in general do not bring any jar?
So this: api(enforcedPlatform("org.jetbrains.kotlin:kotlin-bom:1.4.20")) does add zero dependencies? :)

When it comes to an article I think my idea or name would be - "Avoid dependency hell with a power of BOM and Gradle constraints" or something like that :D

Exactly I added 'allowDependencies()' in order to allow the platform to specify real dependencies so that I could specify the BOMs for other frameworks.

Also, yes adding a platform for the kotlin-bom simply brings in constraints on the versions. So that you can simply specify Kotlin dependencies throughout your project without the version, then update the Kotlin version only on the BOM.

Haha amazing. Thanks!