OpenGL 3.0 SHA256

gistfile1.c

#version 130
#pragma optionNV(unroll all)

uint ROTLEFT(in uint a, in int b) { return (a << b) | (a >> (32-b)); }
uint ROTRIGHT(in uint a, in int b) { return (a >> b) | (a << (32-b)); }

uint CH(in uint x,in uint y,in uint z) { return (x & y) ^ (~x & z); }
uint MAJ(in uint x,in uint y,in uint z) { return (x & y) ^ (x & z) ^ (y & z); }
uint EP0(in uint x) { return ROTRIGHT(x,2) ^ ROTRIGHT(x,13) ^ ROTRIGHT(x,22); }
uint EP1(in uint x) { return ROTRIGHT(x,6) ^ ROTRIGHT(x,11) ^ ROTRIGHT(x,25); }
uint SIG0(in uint x) { return ROTRIGHT(x,7) ^ ROTRIGHT(x,18) ^ (x >> 3); }
uint SIG1(in uint x) { return ROTRIGHT(x,17) ^ ROTRIGHT(x,19) ^ (x >> 10); }

uint k[64] = uint[64](
	0x428a2f98,0x71374491,0xb5c0fbcf,0xe9b5dba5,0x3956c25b,0x59f111f1,0x923f82a4,0xab1c5ed5,
	0xd807aa98,0x12835b01,0x243185be,0x550c7dc3,0x72be5d74,0x80deb1fe,0x9bdc06a7,0xc19bf174,
	0xe49b69c1,0xefbe4786,0x0fc19dc6,0x240ca1cc,0x2de92c6f,0x4a7484aa,0x5cb0a9dc,0x76f988da,
	0x983e5152,0xa831c66d,0xb00327c8,0xbf597fc7,0xc6e00bf3,0xd5a79147,0x06ca6351,0x14292967,
	0x27b70a85,0x2e1b2138,0x4d2c6dfc,0x53380d13,0x650a7354,0x766a0abb,0x81c2c92e,0x92722c85,
	0xa2bfe8a1,0xa81a664b,0xc24b8b70,0xc76c51a3,0xd192e819,0xd6990624,0xf40e3585,0x106aa070,
	0x19a4c116,0x1e376c08,0x2748774c,0x34b0bcb5,0x391c0cb3,0x4ed8aa4a,0x5b9cca4f,0x682e6ff3,
	0x748f82ee,0x78a5636f,0x84c87814,0x8cc70208,0x90befffa,0xa4506ceb,0xbef9a3f7,0xc67178f2
);

uniform uint midstate[8];
uniform uint text[16];

void main() {

	uint a,b,c,d,e,f,g,h,t1,t2,m[64];
	uint ee,eee,eeee;
	int i;

	a = midstate[0];
	b = midstate[1];
	c = midstate[2];
	d = midstate[3];
	e = midstate[4];
	f = midstate[5];
	g = midstate[6];
	h = midstate[7];

	for (i = 0;  i < 16; i++) m[i] = text[i];

	for (; i < 64; i++) m[i] = SIG1(m[i-2]) + m[i-7] + SIG0(m[i-15]) + m[i-16];

	for (i = 0; i < 64; i++) {
		t1 = h + EP1(e) + CH(e,f,g) + k[i] + m[i];
		t2 = EP0(a) + MAJ(a,b,c);
		h = g;
		g = f;
		f = e;
		e = d + t1;
		d = c;
		c = b;
		b = a;
		a = t1 + t2;
	}

	m[0] = midstate[0] + a;
	m[1] = midstate[1] + b;
	m[2] = midstate[2] + c;
	m[3] = midstate[3] + d;
	m[4] = midstate[4] + e;
	m[5] = midstate[5] + f;
	m[6] = midstate[6] + g;
	m[7] = midstate[7] + h;

	a = 0x6a09e667U;
	b = 0xbb67ae85U;
	c = 0x3c6ef372U;
	d = 0xa54ff53aU;
	e = 0x510e527fU;
	f = 0x9b05688cU;
	g = 0x1f83d9abU;
	h = 0x5be0cd19U;

	m[8]  = 0x80000000U;
	m[9]  = 0x00U;
	m[10] = 0x00U;
	m[11] = 0x00U;
	m[12] = 0x00U;
	m[13] = 0x00U;
	m[14] = 0x00U;
	m[15] = 0x100U;

	for (i = 16; i < 64; i++) m[i] = SIG1(m[i-2]) + m[i-7] + SIG0(m[i-15]) + m[i-16];

	for (i = 0; i < 57; i++) {
		t1 = h + EP1(e) + CH(e,f,g) + k[i] + m[i];
		t2 = EP0(a) + MAJ(a,b,c);
		h = g;
		g = f;
		f = e;
		e = d + t1;
		d = c;
		c = b;
		b = a;
		a = t1 + t2;
	}

	eeee = d + h + EP1(e) + CH(e,f,g) + 0x78a5636fU + m[57];
	eee = c + g + EP1(eeee) + CH(eeee,e,f) + 0x84c87814U + m[58];
	ee = b + f + EP1(eee) + CH(eee,eeee,e) + 0x8cc70208U + m[59];
	h = a + e + EP1(ee) + CH(ee,eee,eeee) + 0x90befffaU + m[60];

	if (0x5be0cd19U + h == 0x00U) {
		gl_FragColor=vec4(0.0,1.0,0.0,1.0);
	} else { gl_FragColor=vec4(1.0,0.0,0.0,1.0); }
}