Working gnonlin-git PKGBUILD

PKGBUILD

# Maintainer: Kerrick Staley <mail@kerrickstaley.com>
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Lubosz Sarnecki <lubosz@gmail.com>

pkgname=gnonlin-git
pkgver=20121231
pkgrel=1
pkgdesc='A library for creating non-linear video editors'
arch=('i686' 'x86_64')
url='http://gnonlin.sourceforge.net'
depends=('gstreamer-git' 'gst-plugins-base-git')
provides=('gnonlin=0.11.89.1') #grep AC_INIT src/gnonlin/configure.ac
conflicts=('gnonlin')
options=('!libtool')
license=('LGPL')

_gitroot='git://anongit.freedesktop.org/gstreamer/gnonlin'
_gitname='gnonlin'

build() {
    cd "$srcdir"
    
    msg 'Connecting to GIT server...'
    if [[ -d "$_gitname" ]]; then
        (cd "$_gitname" && git pull origin)
    else
        git clone --depth=1 "$_gitroot" "$_gitname"
    fi
    
    cd "$_gitname"
    if test ! -f common/gst-autogen.sh;
    then
        msg '+ Setting up common submodule'
        git submodule init
    fi
    git submodule update
    cd ..
    
    msg 'GIT checkout done or server timeout'
    msg 'Starting make...'
    
    rm -rf "$_gitname-build"
    cp -r "$_gitname" "$_gitname-build"
    cd "$_gitname-build"
    
    ./autogen.sh --prefix=/usr
    make || return 1
}

package() {
    cd "$srcdir/$_gitname-build"
    make DESTDIR="$pkgdir" install || return 1
}