clutter-gst-git

PKGBUILD

# Current maintainer: Kozec <kozec at kozec dot com>
# Contributor: Alex Anthony <alex.anthony28991 at googlemail.com>
# Adapted from PKGBUILD by atie H. <atie.at.matrix@gmail.com>
# Contributor: Lubosz Sarnecki <lubosz@gmail.com>

pkgname=clutter-gst-git
pkgver=2.99.5.650.2d1a55b 
pkgrel=1
pkgdesc="A GStreamer integration library for Clutter"
arch=('i686' 'x86_64')
url="http://clutter-project.org/"
license=('LGPL')
depends=('clutter>=1.18.0' 'gstreamer')
makedepends=('gtk-doc' 'git')
options=('!libtool')
provides=('clutter-gst='$pkgver)
conflicts=('clutter-gst')
source=(git://git.gnome.org/clutter-gst)
md5sums=('SKIP')

_gitname='clutter-gst'

pkgver() {
  cd $_gitname
  
  major=$(grep "major_version," configure.ac | sed 's/m4_define(clutter_gst_major_version, //' | sed 's/)//')
  minor=$(grep "minor_version," configure.ac | sed 's/m4_define(clutter_gst_minor_version, //' | sed 's/)//')
  micro=$(grep "micro_version," configure.ac | head -1 | sed 's/m4_define(clutter_gst_micro_version, //' | sed 's/)//')
  hash=$(git log --pretty=format:'%h' -n 1)
  revision=$(git rev-list --count HEAD)
  
  echo $major.$minor.$micro.$revision.$hash  
}

build() {
  cd $_gitname
  ./autogen.sh --prefix=/usr
  make
}
 
package() {
  cd $_gitname
  make DESTDIR="$pkgdir" install
}