Skip to content

Instantly share code, notes, and snippets.

@lubosz lubosz/PKGBUILD
Created Jun 22, 2014

Embed
What would you like to do?
gobject-intropection PKGBUILD
# Maintainer: Joao Cordeiro <jlcordeiro at gmail dot com>
# Contributor: <arsenm2@rpi.edu>
# Contributor: Lubosz Sarnecki <lubosz@gmail.com>
pkgname=gobject-introspection-git
pkgver=1.41.0.3202.ed3aa4a
pkgrel=1
pkgdesc="GObject Introspection"
epoch=1
arch=('x86_64' 'i686')
license=('LGPL' 'GPL')
url="http://live.gnome.org/GObjectIntrospection/"
depends=("glib2-git" 'python2' 'python2-mako')
makedepends=('git' 'pkgconfig' 'autoconf' 'gtk-doc'
'bison' 'cairo' 'mesa' 'flex')
provides=("gobject-introspection=${pkgver}")
conflicts=('gobject-introspection' 'gobject-introspection-svn')
replaces=('gobject-introspection-svn')
options=(!makeflags docs !libtool strip)
source=("git://git.gnome.org/gobject-introspection")
md5sums=("SKIP")
_gitname="gobject-introspection"
subver() {
PREFIX="m4_define(gi_$1_version, "
echo $(grep $PREFIX configure.ac | eval sed "'s/$PREFIX//'" | sed 's/)//')
}
pkgver() {
cd $_gitname
major=$(subver major)
minor=$(subver minor)
micro=$(subver micro)
hash=$(git log --pretty=format:'%h' -n 1)
revision=$(git rev-list --count HEAD)
echo $major.$minor.$micro.$revision.$hash
}
build() {
cd $_gitname
export PYTHON=/usr/bin/python2
./autogen.sh --prefix=/usr --disable-static --enable-doctool
make
}
package() {
cd $_gitname
make DESTDIR="$pkgdir" install
sed -i '1s|#!/usr/bin/env python$|&2|' \
"$pkgdir"/usr/lib/gobject-introspection/giscanner/*.py
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.