Internet Café Concurrency Exercise in Perl 6

main.p6

# http://whipperstacker.com/2015/10/05/3-trivial-concurrency-exercises-for-the-confused-newbie-gopher/
unit sub MAIN (
  UInt :$tourists  where * > 0 = 25,
  UInt :$computers where * > 0 = 8,
);

my @computers is Channel;
@computers.send(++$) xx $computers;

loop {
  state @queue = pick *, 1..$tourists;
  once @queue.say;

  given @computers.poll {
    when Nil|@queue.not {
      say “Tourist $_ waiting for turn.” for @queue;
      last;
    }
    default {.&use-computer: @queue.shift}
  }

  LAST {
    given @queue {
      use-computer @computers.receive, .shift while .elems
    }
  }
}

sub use-computer ($computer, $tourist) {
  state @promises;
  say “{:$tourist.kv.join(‘ ’).tc} is on {:$computer.kv.join: ‘ ’}.”;

  given (15..120).rand.round -> $time {
    @promises.push(Promise.in($time ÷ 20).then: {
      say “{:$tourist.kv.join(‘ ’).tc} is done, having spent $time minutes on {:$computer.kv.join: ‘ ’}.”;
      @computers.send: $computer;
    });
  }

  END {
    if @promises {
      await Promise.allof: @promises;
      say ‘The place is empty, let's close up and go to the beach!’;
    }
  }
}