edb 1.0.0 PKGBUILD

PKGBUILD

# Maintainer: revel <revelΘmuub·net>
# Contributor: shild <sxp@bk.ru>
# Contributor: m4tx <m4tx@m4tx.p>

pkgname=edb-debugger
pkgver=1.0.0
pkgrel=1
pkgdesc="EDB (Evan's Debugger) is a Qt5 based binary mode debugger with the goal of having usability on par with OllyDbg."
arch=('i686' 'x86_64')
url='http://www.codef00.com/projects#debugger'
license=('GPL2')
depends=('qt5-xmlpatterns' 'capstone>=3.0')
makedepends=('boost>=1.35.0' 'cmake')
optdepends=('graphviz>=2.38.0')
install=edb.install
source=("https://github.com/eteran/edb-debugger/releases/download/$pkgver/edb-debugger-$pkgver.tgz"
        'edb.desktop'
	'plugin_path.patch')
md5sums=('904414d68157818024b9582d275d2062'
         '8844cd95efef848f8f4a444259491961'
	 '49bedc914539fe2d58fc6aab9434e6f9')
sha256sums=('fab87541042df79ea63254e371d81b84d6b72f78141a6ab92512610ed2b7dfac'
            'af1d0eae06544fbca7a9af2e2f55dc472324abf28402652e88d3b62c1882a132'
	    '68d33f6d1aece55915aea26e188b520d4fdd582e1d3a6484d45d5197fe81fdad')

prepare() {
  cd "edb-debugger-$pkgver"
  patch -p1 -i ../plugin_path.patch
}

build() {
  cd "edb-debugger-$pkgver"
  [ ! -d build ] && mkdir build
  cd build
  cmake -DCMAKE_INSTALL_PREFIX="$pkgdir/usr/" -DDEFAULT_PLUGIN_PATH="/usr/lib/edb/" ..
  make
}

package() {
  cd "edb-debugger-$pkgver"
  cd build

  # install to pkg dir
  make install

  # correct /usr/lib64 -> /usr/lib on x86_64
  [ "$CARCH" = "x86_64" ] && (mv "$pkgdir/usr/lib64" "$pkgdir/usr/lib")

  # icons
  cd ..
  install -Dm644 src/images/edb48-logo.png "$pkgdir/usr/share/pixmaps/edb.png"
  install -Dm644 src/images/edb48-logo.png "$pkgdir/usr/share/icons/hicolor/48x48/apps/edb.png"

  # install desktop file
  cd ..
  install -Dm644 edb.desktop "$pkgdir/usr/share/applications/edb.desktop"
}