matchsticks puzzlescript

script.txt

title Matchsticks

========
OBJECTS
========

Background 
GREEN  

Target 
DarkBlue
00000
0...0
0.0.0
0...0
00000

Wall 
BROWN

Player 
Transparent   

Crate
Orange 
.....
.000.
.0.0.
.000.
.....

PlayerUp
Blue LightBlue White
..0..
..1..
..2..
..2..
.....

PlayerUpDown
Blue LightBlue White
..0..
..1..
..2..
..1..
..0..

PlayerDown
Blue LightBlue White
.....
..2..
..2..
..1..
..0..


PlayerLeft
Blue LightBlue White
.....
.....
0122.
.....
.....

PlayerRight
Blue LightBlue White
.....
.....
.2210
.....
.....

PlayerLeftRight
Blue LightBlue White
.....
.....
01210
.....
.....

Hole
Black

EdgeHole
Transparent

=======
LEGEND
=======

. = Background
# = Wall
* = Crate and Background
@ = Crate and Target
O = Target and Background
^ = Player and PlayerUp
> = Player and PlayerDown
< = Player and PlayerLeft
v = Player and PlayerRight
" = Player and PlayerUp and PlayerRight
| = Player and PlayerUpDown
- = Player and PlayerLeftRight
+ = Player and PlayerUpDown and PlayerLeftRight
H = Hole

PlayerDirection = PlayerUp or PlayerDown or PlayerUpDown or PlayerLeft or PlayerRight or PlayerLeftRight

Moveable = Crate or Player or PlayerDirection
MoveableOrHole = Moveable or Hole
Solid = Moveable or Wall or Hole

=======
SOUNDS
=======

================
COLLISIONLAYERS
================

Background
Hole
Target, EdgeHole
Player, Wall, Crate
PlayerUp, PlayerDown, PlayerUpDown
PlayerLeft, PlayerRight, PlayerLeftRight

======
RULES     
======     

[ Hole No EdgeHole ] -> [ Hole EdgeHole ]
[ > Player ] [ | EdgeHole | ] -> [ > Player ] [ | | ]

[ Up Player No PlayerUp No PlayerUpDown ] -> [ Player ]
[ Down Player No PlayerDown No PlayerUpDown ] -> [ Player ]
[ Left Player No PlayerLeft No PlayerLeftRight ] -> [ Player ]
[ Right Player No PlayerRight No PlayerLeftRight ] -> [ Player ]

[ > Player PlayerDirection ] -> [ > Player > PlayerDirection ]

[ > MoveableOrHole | MoveableOrHole ] -> [  > MoveableOrHole | > MoveableOrHole ]
+ [ Hole EdgeHole | ... | > Hole EdgeHole ] -> [ > Hole EdgeHole | ... | > Hole EdgeHole ]

[ > MoveableOrHole | Stationary Solid ] -> [ MoveableOrHole | Solid ]
+ [ Hole EdgeHole | Stationary Solid | ... | > Hole EdgeHole ] -> [ Hole EdgeHole | Stationary Solid | ... | Hole EdgeHole ]

[ > Hole ] -> [ Hole ]

[ > Moveable | Hole ] -> [ | > Moveable Hole ]
+ [ > Moveable | No Solid ] -> [ | Moveable ]
+ [ EdgeHole | ... | > Moveable EdgeHole ] -> [ > Moveable EdgeHole | ... | EdgeHole ]

[ EdgeHole ] -> []

==============
WINCONDITIONS
==============

All Target on Crate     

=======     
LEVELS
=======


HHHHH
H.*.H
H.+.H
HO..H
HHHHH

hhhhhhh
h.*...h
h..|..h
ho..-.h
h.....h
h.....h
hhhhhhh

hhhhhhhhhhhh
h..........h
h..........h
h..hh..hh..h
h..hh..hh..h
h........||h
h-.......**h
h..hh..hh..h
h..hh..hh..h
h.........o#
h*.......oo#
hhhhhhhhh###


#########
#.....o.#
#.....*.#
#....>..#
#...>...#
#.v>....#
#.....^.#
#.......#
#...***.#
#...ooo.#
#########

#########
#+......#
#..*....#
#.*.*...#
#..*##.##
#...#...#
#.....oo#
#...#.oo#
#########

hhhhhhhh
hh*hhhhh
ho+.#..h
hh#hhh.h
hh.hhh.h
hh.#...h
hhhhhhhh

#########
#.......#
#.|.....#
#.*.....#
#.*.....#
#.*..#o.#
#-*..o.o#
#....#o.#
#.......#
#########