Skip to content

Instantly share code, notes, and snippets.

@maly

maly/dictator.bas

Created February 22, 2020 15:45
Show Gist options
  • Star 0 You must be signed in to star a gist
  • Fork 0 You must be signed in to fork a gist
  • Save maly/3d7816d4f94afa81ef1f90253382908c to your computer and use it in GitHub Desktop.
Save maly/3d7816d4f94afa81ef1f90253382908c to your computer and use it in GitHub Desktop.
Download ZIP
Raw
dictator.bas
1 REM :H\ THEN ? THEN ? THEN ? THEN BORDER OPEN # RETURN <> THEN PI OPEN # RETURN <> RESTORE MERGE OR !FORMAT :READ \GOR STEP FORMAT \CDRAW FDRAW # STEP OVER \CDRAW FDRAW #STR$ VERIFY STR$ MOVE LLIST <> .!CONTINUE FOR RESTORE X @OR THEN  ~ THEN IN #NEXT STR$ GO SUB LLIST ### STEP L]STR$ BRIGHT <> OR FOR H:H\ THEN ? THEN ? THEN ? THEN BORDER OPEN # 6SAVE THEN PI OPEN # 6ASAVE STR$ OPEN # STR$ <> ....................................
2 REM pUSR x<LIST LPRINT <OSAVE LPRINT `|8LPRINT PAUSE ><CEp STR$ CgCOPY COPY COPY COPY LIST SAVE DRAW RETURN ?7""!COPY COPY COPY w##ACS ACS COPY CAT CIRCLE CIRCLE DRAW RETURN 3.'COPY 3RUN jMERGE COPY 0AT TSAVE >#COPY 5dBIN COPY USR `8SAVE ~COPY USR @ RETURN  USR `COPY ~`USR ~COPY COPY COPY COPY USR LIST !?COPY COPY COPY COPY COPY COPY NOT COPY COPY LPRINT DRAW COPY COPY ........
3 REM INTR
4 BORDER 1:PAPER 0:INK 7:GO SUB cls:PRINT AT 4,2;"DIKTATOR";AT 8,2;"Autor:"
5 PRINT AT 10,2;"Don PRIESTLEY"
7 PRINT AT 14,2;INK 9;"Copyright D kTRONICS 1983"
8 PRINT AT 17,2;"Preklad Frantisek Fuka-FUXOFT"
9 RETURN
10 REM FX
12 FOR i=1 TO 10
14 IF INT (RND *2) THEN GO TO 20
15 POKE 23779,RND *100+150:BORDER INT (RND *6)+1:LET y=USR 23780:IF PEEK 23779<175 THEN GO TO 14
16 BORDER 0
20 POKE 23779,RND *10+20:FOR a=5 TO RND *10+10:LET y=USR 23780:NEXT a
60 NEXT i
62 RETURN
70 POKE 23779,20:FOR a=5 TO RND *10+50:LET y=USR 23780:NEXT a
72 RETURN
80 LET co=5010:LET cls=1300:LET s$=" "
82 GO SUB 4:LET hst=0
84 LET b$="123456789":LET c$="987654321"
110 DIM d$(49,49):DIM g$(8,22)
112 RESTORE 6101
116 FOR a=1 TO 49:READ d$(a):NEXT a
120 GO SUB co:GO SUB 4e3
130 REM CYCLE
140 RESTORE 6150:FOR a=1 TO 8:READ g$(a):NEXT a
200 FOR a=1 TO 49:LET d$(a,1)="N":NEXT a
202 LET bk=1e3
203 LET esc=0
204 LET mpy=60
206 LET st=4
208 LET sw=0
210 LET d=10
212 LET mth=0
215 LET coy=5e3
218 LET ad=1e3
220 LET pl=1400
222 LET pc=0
224 LET cad=1980
226 LET act=790
227 LET gr=23675
228 LET bkr=900
230 LET tran=1600
232 LET pr=1700
234 LET ass=1500
236 LET aid=2060
238 LET dec=2500
240 LET rev=1800
242 LET end=3000
244 LET str=10
246 LET tune=1570
247 LET news=2750
248 LET cls=1300
249 LET war=4200
250 BORDER 1:PAPER 7:GO SUB cls
252 INK 0:GO SUB cls:PRINT AT 3,7;PAPER 5;FLASH 1;"VITEJTE v KANCELARI"'''
254 PRINT "Nejlepsi DIKTATOR nasi milovane"''
256 PRINT "RITIMBY mel celkove hodnoceni"''
258 PRINT hst;" bodu"
259 PRINT ''
260 IF hst<= 0 THEN PRINT "Protoze toto je vas prvni pokus,"''"budete nepochybne LEPSI !"''
264 IF hst>= 1 THEN PRINT "Muzete se pokusit ziskat "''hst+1;" bodu !!"''
266 PRINT "Zacneme ZPRAVOU O STAVU POKLADNY"''
268 PRINT "a POLICEJNI ZPRAVOU. (ZDARMA)"
270 GO SUB co
272 GO SUB act:GO SUB co
274 GO SUB pr+20:GO TO 600
400 REM PICS
411 POKE gr,40:POKE gr+1,94:GO TO 420
412 POKE gr,168:POKE gr+1,93:GO TO 420
413 POKE gr,232:POKE gr+1,93
420 PRINT AT 6,2;" ";AT 7,2;" "
422 RETURN
600 REM REQUESTS
601 LET c=1
603 LET low=INT (RND *3)+2
604 LET str=INT (RND *3)+10
610 LET mth=mth+1
612 BORDER 1:PAPER 6:GO SUB cls
613 PRINT AT 10,11;BRIGHT 1;mth;BRIGHT 0;". MESIC"
614 PAUSE 50
616 GO SUB pl
618 IF bk<0 THEN GO SUB bkr
620 IF bk>0 THEN LET bk=bk-mpy
622 PAPER 6:GO SUB cls
624 PRINT AT 0,0;PAPER 4;s$;s$;s$;s$;s$;AT 3,12;"AUDIENCE"
630 LET r=INT (RND *24)+1
632 FOR a=1 TO 22:IF d$(r,1)="N" THEN GO TO 648
634 LET r=(r-INT (r/24)*24)+1:NEXT a
640 FOR a=1 TO 24:LET d$(a,1)="N":NEXT a:GO TO 630
648 LET d$(r,1)="*"
650 LET gs=INT ((r-1)/8)+1:BORDER gs
652 LET t$=g$(gs,6 TO CODE g$(gs,5)-20)
654 LET r$=d$(r)
655 GO SUB 410+gs
656 PRINT AT 10,2;t$;" prichazeji"'TAB 16;"s zadosti..."
662 PRINT AT 14,5;"Dovoli VASE EXCELENCE";AT 16,0;BRIGHT 1;r$(18 TO )
666 GO SUB co:BORDER 0:GO SUB ad
670 REM choice
684 GO SUB cls:PRINT AT 1,9;" ROZHODNUTI "
688 PRINT :PRINT TAB (21-LEN t$)/2;PAPER gs;t$;" si preji"
690 PRINT AT 5,0;BRIGHT 1;r$(18 TO )''BRIGHT 0;PAPER 1;s$
694 IF NOT c THEN GO TO 730:LET a=0
696 GO SUB cad:PRINT :PRINT INK 4;s$
698 IF c=0 THEN GO TO 730
722 GO SUB coy
726 IF k$="y" THEN GO TO 760
728 GO TO 740
730 GO SUB cls:PRINT AT 10,1;"NEMATE dostatek penez na"
731 PRINT AT 12,1;"VYDAJE za toto rozhodnuti"
732 PRINT AT 15,4;"Vase odpoved musi byt NE":PAUSE 250
734 LET c=1
740 LET x=VAL g$(gs,1)
744 LET y=CODE (r$(gs+3))-77
746 LET x=x-y
748 IF x<0 THEN LET x=0
750 LET g$(gs,1)=STR$ x
751 GO SUB cls
752 GO SUB act:GO TO 766
760 GO SUB act:GO SUB tran:GO SUB act+6
766 GO SUB pl:GO SUB co
775 GO SUB ass:IF d=0 THEN GO TO end
778 GO SUB war:IF d=0OR esc=1 THEN GO TO end
779 GO SUB pl
780 GO SUB pr:GO TO dec
790 REM ACOUNT
792 PAPER 7:GO SUB cls:BORDER 4
794 FOR a=1 TO 24:PRINT INK 4;"$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$":NEXT a
796 POKE gr,104:POKE gr+1,94
798 PRINT AT 3,1;PAPER 4;" ";AT 4,1;"";AT 5,1;" "
824 PRINT AT 8,9;"STAV POKLADNY"
825 PAPER 1:INK 9
826 BRIGHT 1:PRINT AT 11,1;" POKLADNA";
828 IF INT bk>= 0 THEN PRINT " obsahuje $";
830 IF bk<0 THEN PRINT " DLUZI $";
831 PRINT ABS INT bk;",000 "
832 PRINT AT 14,1;" MESICNI VYDAJE jsou $";mpy;",000 "
838 IF sw>0 THEN PRINT AT 17,2;"[Ve SVYCARSKU je $";sw;",000]"
842 BRIGHT 0:RETURN
900 REM BANKRUPT
910 GO SUB cls
914 PRINT AT 5,5;"POKLADNA ZBANKROTOVALA"
918 PRINT AT 9,0;"Vase popularita u ARMADY a u"''
920 PRINT " TAJNE POLICIE klesne !"'''
922 PRINT " Sila POLICIE klesne"''
924 PRINT "a VASE vlastni SILA take KLESNE"
930 IF g$(1,1)>"0" THEN LET g$(1,1)=STR$ (VAL g$(1,1)-1)
932 IF g$(6,1)>"0" THEN LET g$(6,1)=STR$ (VAL g$(6,1)-1)
933 IF g$(6,2)>"0" THEN LET g$(6,2)=STR$ (VAL g$(6,2)-1)
934 IF st>0 THEN LET st=st-1
940 PAUSE 250:GO SUB pl:GO SUB pr
944 RETURN
1000 REM ADvice
1002 PAPER 4:BORDER 1:GO SUB cls
1004 FOR a=1 TO 19:PRINT AT a,11;"? ZPRAVU ?":NEXT a
1010 GO SUB coy:PAPER 6:GO SUB cls
1014 IF k$<> "y" THEN RETURN
1022 PRINT AT 1,0;INVERSE 1;d$(r,18 TO ):PRINT
1026 PRINT AT 3,0;"Vase POPULARITA ....":PRINT
1027 FOR a=1 TO 8
1028 LET x=CODE d$(r,a+3)-77:IF x=0 THEN GO TO 1034
1029 PRINT TAB 2;g$(a,6 TO );TAB 21;
1031 IF x>0 THEN PRINT "+";
1032 PRINT x;
1033 IF gs=aAND r<25 THEN PRINT INVERSE 1;INK gs;"< "
1034 NEXT a
1035 PRINT :PRINT
1036 PRINT "SILA ...":PRINT
1038 FOR a=1 TO 6
1039 LET x=CODE d$(r,a+11)-77:IF x=0 THEN GO TO 1048
1041 PRINT TAB 2;g$(a,6 TO );TAB 21;
1042 IF x>0 THEN PRINT "+";
1044 PRINT x
1048 NEXT a
1050 GO SUB co:GO SUB cls:RETURN
1300 REM CLS
1310 POKE 23659,2:CLS :POKE 23659,0:PRINT AT 22,0;s$;s$:BEEP .1,40:PRINT AT 0,0;:RETURN
1400 REM PLOT
1410 IF mth<= 2 THEN RETURN
1420 FOR a=1 TO 3:LET g$(a,3 TO 4)="::":NEXT a
1426 IF mth<pc THEN RETURN
1430 FOR a=1 TO 3
1432 IF VAL g$(a,1)>low THEN GO TO 1450
1436 FOR p=1 TO 6
1438 IF a=pOR VAL g$(p,1)>low THEN GO TO 1441
1440 IF VAL g$(p,2)+VAL g$(a,2)>= str THEN GO TO 1446
1441 NEXT p
1442 LET g$(a,3)="A":GO TO 1450
1446 LET g$(a,3)="R"
1448 LET g$(a,4)=STR$ p
1450 NEXT a
1452 RETURN
1500 REM ASSASSIN
1510 LET r=INT (RND *3)+1
1514 IF g$(r,3)<> "A" THEN RETURN
1516 PAPER 0:BORDER 0:GO SUB cls:PRINT AT 10,8;"POKUS O ATENTAT"
1518 PRINT AT 20,10;"(";g$(r,6 TO CODE g$(r,5)-20);")"
1520 FOR a=60 TO 1 STEP -.5:POKE 23886,a:LET i=USR 23884:NEXT a:POKE 23886,70
1522 GO SUB cls:PAUSE 30:GO SUB 70:PAUSE 50
1526 IF g$(1,3)="A"AND g$(2,3)="A"AND g$(3,3)="A" THEN GO TO 1546
1540 IF VAL g$(6,1)>lowOR VAL g$(6,2)>lowOR INT (RND *2) THEN GO TO 1554
1546 BORDER 0:PAPER 0:GO SUB cls:PRINT AT 12,10;"Jste MRTEV !"
1548 BEEP 3,-40
1550 LET d=0:RETURN
1554 BORDER 0:PAPER 7:GO SUB cls:PRINT AT 12,8;" NEZDARENY pokus "
1556 POKE 23886,50:LET a=USR 23842
1560 RETURN
1570 REM TUNE
1572 FOR a=1 TO LEN m$ STEP 2
1574 IF CODE m$(a+1)=32 THEN PAUSE CODE m$(a)/4:GO TO 1578
1576 BEEP (CODE m$(a)-48)/6,CODE m$(a+1)-105
1578 NEXT a
1580 RETURN
1600 REM TRANSFER
1610 LET d$(r,1)="*"
1620 LET t$=d$(r,4 TO 11)
1621 FOR a=1 TO 8
1622 IF t$(a)="M" THEN GO TO 1632
1624 LET x=VAL g$(a,1)+(CODE t$(a)-77)
1626 IF x>9 THEN LET x=9
1628 IF x<0 THEN LET x=0
1630 LET g$(a,1)=STR$ x
1632 NEXT a
1638 LET t$=d$(r,12 TO 17)
1640 FOR a=1 TO 6
1642 IF t$(a)="M" THEN GO TO 1652
1644 LET x=VAL g$(a,2)+(CODE t$(a)-77)
1646 IF x>9 THEN LET x=9
1648 IF x<0 THEN LET x=0
1650 LET g$(a,2)=STR$ x
1652 NEXT a
1660 LET bk=bk+cst
1662 LET mpy=mpy-mcst
1664 IF mpy<0 THEN LET mpy=0
1666 RETURN
1700 REM POLICE REPORT
1702 INK 9:BORDER 0:PAPER 0:GO SUB cls
1703 POKE gr,104:POKE gr+1,94
1705 PRINT AT 0,1;INK 6;INVERSE 1;"";AT 1,1;""
1709 PRINT AT 6,6;"ZPRAVA TAJNE POLICIE";
1710 IF bk<= 0OR VAL g$(6,1)<= lowOR VAL g$(6,2)<= low THEN GO TO 1764
1713 PRINT "?":PRINT AT 12,8;"( stoji $1000 )"
1714 GO SUB coy
1715 IF k$<> "y" THEN RETURN
1718 LET bk=bk-1
1720 PAPER 0:GO SUB cls:BORDER 0
1721 PRINT mth;". MESIC";AT 3,0;INK 1;FLASH 1;s$
1722 PRINT AT 3,8;INVERSE 1;" ZPRAVA POLICIE"
1723 PRINT AT 5,14;INVERSE 1;"";AT 6,14;""
1724 PRINT AT 6,1;"POPULARITA";AT 6,21;" SILA "
1725 RESTORE 6200:FOR a=1 TO 8:READ k$
1726 PRINT AT 7+a,11;PAPER 6;FLASH 0+(g$(a,3)="R");k$
1728 PRINT AT 7+a,10;PAPER 7;BRIGHT 1;a
1729 IF a<= 3AND g$(a,3)="R" THEN PRINT AT 7+a,21;PAPER 7;VAL g$(a,4)
1732 LET x=VAL g$(a,1):PRINT AT 7+a,10-x;INK 7;PAPER 4;c$(10-x TO )
1734 IF a<= 3AND g$(a,3)="A" THEN PRINT AT a+7,21;PAPER 7;"A"
1736 NEXT a
1738 FOR a=1 TO 6:PRINT AT 7+a,22;PAPER 2;INK 7;b$( TO VAL g$(a,2)):NEXT a
1742 PRINT AT 17,1;"Vase SILA je ";st
1744 PRINT AT 19,1;"SILA potrebna k REVOLUCI je ";str
1750 GO SUB co:PAPER 4:GO SUB cls:RETURN
1764 PRINT AT 10,9;"NENI K DISPOZICI"''
1766 IF VAL g$(6,1)<= low THEN PRINT TAB 3;"Vase POPULARITA u nas je ";g$(6,1)''
1768 IF VAL g$(6,2)<= low THEN PRINT TAB 3;"Sila POLICIE je ";g$(6,2)''
1769 IF bk<= 0 THEN PRINT TAB 3;"Nemuzete si DOVOLIT zpravu"
1770 POKE 23886,30:FOR a=1 TO 80:LET i=USR 23884:NEXT a
1772 POKE 23886,50:RETURN
1800 REM REVOLUTION
1801 GO SUB news
1802 FOR a=1 TO 3:LET r=INT (RND *3)+1
1804 IF g$(r,3)="R" THEN GO TO 1810
1806 NEXT a
1807 GO TO 600
1810 POKE 23886,50:INK 0:BORDER 2:FLASH 1:PAPER 2:GO SUB cls:INK 9:PRINT AT 10,12;FLASH 0;"REVOLUCE"
1812 FOR a=1 TO 5:BEEP .5,20:BEEP .5,10:NEXT a
1814 FLASH 0:PAPER 6:GO SUB cls
1816 PRINT AT 12,9;"POKUS O UTEK ?":GO SUB coy
1830 GO SUB cls:IF k$<> "y" THEN GO TO 1850
1832 IF d$(36,1)="*" THEN GO TO 1842
1833 PRINT AT 10,2;"Musite se dostat pres HORY";AT 12,11;"do LEFTOTA"
1834 PAUSE 200:GO SUB cls
1836 IF INT (RND *((VAL g$(4,2)/3)+.4)) THEN GO TO 1839
1837 PRINT AT 9,4;"PARTYZANI vas NECHYTILI":LET i=USR 23842:GO TO end
1839 PAPER 0:GO SUB cls
1840 LET d=0:PAUSE 50:GO SUB 70:PRINT AT 12,7;"PARTYZANI OSLAVUJI":GO SUB 70:GO TO end
1842 IF INT (RND *3)=0 THEN GO TO 1845
1843 PRINT AT 12,4;"UNIKL JSTE HELIKOPTEROU":LET i=USR 23842:GO TO end
1845 PRINT AT 10,2;"HELIKOPTERA NEODSTARTOVALA !"
1846 PAUSE 150
1847 GO SUB cls:GO TO 1833
1850 LET x=VAL g$(r,2)+VAL g$(VAL g$(r,4),2)
1852 PRINT AT 2,0;g$(r,6 TO CODE g$(r,5)-20);" a ";g$(VAL g$(r,4),6 TO CODE g$(VAL g$(r,4),5)-20);" se SPOJILI !"
1856 PRINT ''
1857 PRINT "Jejich celkova sila je ";x
1858 PRINT ''"KOHO pozadate O POMOC ?"
1860 LET z=1:FOR a=1 TO 6
1862 IF VAL g$(a,1)<= low THEN GO TO 1868
1864 PRINT TAB 6;a;" .";g$(a,6 TO CODE g$(a,5)-20);" ?"
1866 LET z=0
1868 NEXT a
1869 IF z THEN GO TO 1890
1870 GO SUB co:IF k$<"1"OR k$>"6" THEN GO TO 1870
1878 IF VAL g$(VAL k$,1)<= low THEN GO TO 1884
1880 LET h=VAL k$:GO TO 1893
1884 GO SUB cls:PRINT AT 12,5;"Delate si LEGRACI !":GO TO 1846
1890 GO SUB cls:PRINT AT 8,7;"ZUSTAL jste SAM !!"
1892 GO SUB co
1893 GO SUB cls
1894 PRINT AT 8,0;"VASE SILA je ";st
1895 PRINT ''g$(h,6 TO CODE g$(h,5)-20);" maji silu ";g$(h,2)
1896 PRINT ''"Sila REVOLUCIONARU je ";x
1898 PAUSE 250
1900 PAPER 7:GO SUB cls:PRINT AT 12,8;"REVOLUCE ZACALA"
1904 GO SUB 10
1914 IF x<= st+VAL g$(h,2)+INT (RND *3)-1 THEN GO TO 1950
1922 BORDER 0:PAPER 0:GO SUB cls:PRINT AT 10,8;"Byl jste PORAZEN"
1923 PRINT AT 12,9;"a ";FLASH 1;"ZLIKVIDOVAN"
1924 GO SUB 70
1926 LET d=0:PAUSE 50:GO TO end
1950 BORDER 0:GO SUB cls:PRINT AT 10,4;"REVOLUCE byla POTLACENA"
1952 LET a=USR 23842
1954 PRINT AT 0,0;:FOR a=1 TO 22:PRINT PAPER INT (RND *5)+1;s$:NEXT a
1955 PRINT AT 10,0;"Potrestat REVOLUCIONARE ?"
1956 GO SUB coy:IF k$<> "y" THEN GO TO 1968
1960 FOR n=1 TO 3:GO SUB 70:LET y=SQR PI /PI :NEXT n
1964 LET g$(r,1 TO 2)="00"
1966 LET g$(VAL g$(r,4),1 TO 2)="00"
1968 LET g$(h,2)="9"
1969 LET pc=mth+2:GO SUB pl:GO SUB pr:GO TO 600
1980 REM CASH ADVICE
1990 LET cst=10*(CODE d$(r,2)-77)
1992 LET mcst=CODE d$(r,3)-77
1994 IF NOT cstAND NOT mcst THEN GO TO 2030
1996 PRINT AT 9,1;"Toto rozhodnuti by":PRINT
1998 IF NOT cst THEN GO TO 2014
2002 IF cst>0 THEN PRINT " PRIDALO do";
2004 IF cst<0 THEN PRINT " VZALO z";
2008 PRINT " POKLADNY $";ABS cst;",000":PRINT
2010 IF NOT mcst THEN GO TO 2020
2012 PRINT " a";
2014 IF mcst<0 THEN PRINT " ZVYSILO";
2016 IF mcst>0 THEN PRINT " SNIZILO";
2018 PRINT " MESICNI VYDAJE"'" o $";ABS mcst;",000"
2020 IF bk+cst>0 THEN LET c=1:RETURN
2021 IF (cst<0OR mcst<0)AND (bk+cst<0OR bk+mcst<0) THEN GO TO 2034
2022 LET c=1:RETURN
2030 LET c=1:PRINT AT 10,4;"NEZMENI TO STAV POKLADNY":RETURN
2034 PAUSE 250:LET c=0:GO SUB cls
2037 PRINT AT 5,0;d$(r,18 TO )
2039 PRINT AT 8,3;"PENIZE na toto rozhodnuti"
2040 PRINT :PRINT TAB 7;"NEJSOU V POKLADNE"'''
2042 IF d$(38,1)="N" THEN PRINT " Mozna by pomohli RUSOVE...":PRINT
2044 IF d$(39,1)="N" THEN PRINT " AMERICANE jsou stedri lide...":PRINT
2046 PAUSE 350:RETURN
2060 REM AID
2062 BORDER 2:PAPER 6:GO SUB cls:PRINT :PRINT PAPER 2;" ZADOST O ZAHRANICNI POMOC "
2064 PRINT AT 12,13;FLASH 1;"MOMENT":PAUSE 50
2066 LET x=VAL k$-1
2068 IF NOT x THEN LET m$="2g2d3i4d2 2g2d3i4d"
2070 IF x THEN LET m$="2m1j3f3j3m4r1 2v1t3r3j3l4m"
2072 GO SUB tune
2088 IF mth<INT (RND *5)+3 THEN GO TO 2138
2112 IF d$(38+x,1)="*" THEN GO TO 2128
2113 IF VAL g$(7+x,1)<= low THEN GO TO 2132
2114 IF NOT x THEN PRINT AT 12,0;"RUSOVE";
2115 IF x THEN PRINT AT 12,0;"AMERICANE";
2116 PRINT " vam prenechaji"
2117 LET y=VAL g$(7+x,1)*30+INT (RND *200)
2118 PRINT AT 14,7;y;",000 DOLARU"
2120 LET bk=bk+y
2124 LET d$(38+x,1)="*":GO TO 2140
2128 PRINT AT 12,1;"Je mi lito,ale UZ ZADNE PUJCKY":GO TO 2140
2132 IF NOT x THEN PRINT AT 12,12;PAPER 2;"NIKAGDA!"
2134 IF x THEN PRINT AT 12,12;PAPER 1;"""nuts !"""
2136 GO SUB co:RETURN
2138 PRINT AT 12,6;"Jeste je prilis brzy"
2140 GO SUB co:RETURN
2500 REM DECISION
2506 PAPER 6:GO SUB cls
2510 BORDER 1:FOR a=1 TO 22:PRINT INVERSE 1;INK 2;"********************************":NEXT a
2522 PRINT AT 3,5;"PRESIDENTOVO ROZHODNUTI"
2530 INK 9:PRINT AT 6,1;"Muzete zkusit ..."
2534 PRINT AT 8,4;"1. ZVYHODNIT SKUPINU "
2536 PRINT AT 10,4;"2. ZVYHODNIT VSECHNY "
2538 PRINT AT 12,4;"3. ZVETSIT sve SANCE "
2540 PRINT AT 14,4;"4. ZISKAT nejake PENIZE "
2542 PRINT AT 16,4;"5. POSILIT SKUPINU "
2550 GO SUB co:GO SUB cls
2560 IF k$<"1"OR k$>"5" THEN GO TO 2746
2562 IF k$="1" THEN LET x$="-2"
2564 IF k$="2" THEN LET x$="35"
2566 IF k$="3" THEN LET x$="69"
2568 IF k$="4" THEN LET x$=":<"
2570 IF k$="5" THEN LET x$="=?"
2572 PRINT AT (20-(((CODE x$(2)-20)-(CODE x$(1)-20))*3))*.5,0
2574 LET y=1:LET z=1
2578 FOR a=CODE x$(1)-20 TO CODE x$(2)-20
2580 IF d$(a,1)="*" THEN GO TO 2592
2582 LET z=0
2588 PRINT y;".":PRINT d$(a,18 TO ):PRINT
2593 LET y=y+1
2594 NEXT a
2596 IF z THEN GO TO 2600
2597 GO SUB co:GO TO 2620
2600 PRINT AT 12,2;"Tato sekce jiz byla VYUZITA"
2602 PAUSE 150:GO TO dec
2605
2628 IF k$<"0"OR k$>"6" THEN GO TO dec
2630 IF VAL k$<1OR VAL k$>(CODE x$(2)-20)+1-(CODE x$-20) THEN GO TO dec
2634 LET r=((CODE x$)-20)+VAL k$-1
2635 IF d$(r,1)="*" THEN GO TO dec
2636 IF r=38OR r=39 THEN GO TO 2670
2642 IF r=37 THEN GO TO 2680
2644 GO SUB ad
2646 PRINT AT 4,0;BRIGHT 1;d$(r,18 TO )
2648 GO SUB cad
2650 IF NOT c THEN PAUSE 200:GO TO dec
2651 PRINT AT 4,0;BRIGHT 1;d$(r,18 TO )
2652 GO SUB coy
2653 IF k$<> "y" THEN GO TO dec
2654 IF r=35 THEN GO TO 2674
2656 GO SUB act:GO SUB tran
2660 GO TO 2740
2670 GO SUB aid:GO SUB act:GO TO 2741
2674 LET st=st+2:GO SUB act
2676 GO SUB tran+20:GO TO 2740
2680 GO SUB cls:PRINT AT 3,0;INVERSE 1;" PREVOD DO SVYCARSKE BANKY "'''
2685 LET x=INT (bk/2):IF x<1 THEN GO TO 2720
2687 PRINT "Pokladna obsahovala $";INT bk;",000"
2690 LET sw=sw+x:LET bk=bk-x
2692 PAUSE 100
2694 PRINT :PRINT :PRINT "$";x;",000 bylo PREVEDENO":GO TO 2736
2720 PRINT AT 12,7;"ZADNY PREVOD":PAUSE 100
2740 GO SUB 825
2741 GO SUB pl:GO SUB co
2746 GO SUB pr:GO TO rev
2750 REM NEWS
2760 IF INT (RND *3) THEN RETURN
2764 LET r=INT (RND *6)+44
2768 FOR a=1 TO 6
2770 IF d$(r,1)="N" THEN GO TO 2780
2772 LET r=r+1:IF r=50 THEN LET r=44
2774 NEXT a
2776 RETURN
2780 BORDER 1:PAPER 7:INK 0:FLASH 1:GO SUB cls:FLASH 0:PRINT AT 10,12;"TELEGRAM"
2782 FOR a=1 TO 10:BEEP .6,30:NEXT a
2784 GO SUB cls:PRINT AT 10,12;"TELEGRAM"
2786 PRINT AT 14,0;d$(r,18 TO )
2788 INK 9:PAUSE 100
2796 GO SUB tran:GO SUB pl
2800 GO SUB pr
2806 RETURN
3000 REM END
3004 IF d THEN PAUSE 100:GO TO 3026
3010 PAUSE 50:LET m$="4d3d1d3d3g1f2f1d2d1d5d"
3012 GO SUB tune
3026 LET x=0:FOR a=1 TO 8:LET x=x+VAL g$(a,1):NEXT a
3030 BORDER 5:PAPER 6:GO SUB cls
3035 PRINT AT 3,8;"Vase OHODNOCENI"
3050 PRINT :PRINT " Celkova POPULARITA - ";TAB 28;x
3052 PRINT :PRINT " DELKA vlady (";mth;"x3) - ";TAB 28;mth*3:LET x=x+mth*3
3058 IF NOT d THEN GO TO 3072
3062 PRINT :PRINT " Za PREZITI - ";TAB 28;d
3068 PRINT :PRINT " Za ZACHRANENE PENIZE "'" ($";sw;",000 /10,000) -";TAB 28;INT (sw/10)
3070 LET x=x+d+INT (sw/10)
3074 PRINT :PRINT :PRINT " Vas soucet je ";TAB 28;BRIGHT 1;x
3082 IF x>hst THEN LET hst=x
3084 PRINT :PRINT "[ Zatim nejlepsi skore je ";hst;" ]"
3086 GO SUB co:GO SUB cls
3090 BORDER 0:PAPER 0:GO SUB cls:PRINT AT 1,13;FLASH 1;"KONECNA"
3092 GO SUB pr+22:GO SUB 4:GO SUB co:GO SUB cls:GO TO 140
4000 REM TITLE
4002 GO SUB cls
4010 PRINT AT 0,0;:FLASH 1
4020 BORDER 0:INK 9:PAPER 5:FOR a=1 TO 48
4030 PRINT "DIKTATORDIKTATOR";
4045 BEEP .01,40-a+RND *10
4050 NEXT a
4060 POKE 23659,2:FOR a=1 TO 50:BEEP .03,a:NEXT a
4070 FLASH 0:FOR a=8 TO 19
4080 PRINT AT a,7;PAPER 4;INK 2;""
4090 NEXT a
4100 FOR a=8 TO 19:PRINT AT a,11;PAPER 1;" ":NEXT a
4110 PRINT AT 3,7;PAPER 7;"Stisknete tlacitko";AT 5,4;"a stanete se DIKTATOREM"
4120 PAPER 4:PRINT AT 10,12;"RITIMBAN";AT 16,12;"REPUBLIC"
4130 PRINT AT 12,13;PAPER 1;INK 6;"******";AT 13,13;" ** ";AT 14,13;"******"
4140 LET t$="KPKKMKIHK`KMRPOMOP"
4150 FOR a=1 TO LEN t$
4155 IF INKEY$ <> "" THEN RETURN
4160 LET x=CODE t$(a)-80
4170 IF x=16 THEN PAUSE 20:GO TO 4190
4180 BEEP .5,x
4190 NEXT a
4192 PAUSE 30:GO TO 4150
4200 REM WAR
4208 IF VAL g$(5,1)>low THEN RETURN
4210 IF VAL g$(5,2)<low THEN RETURN
4212 IF NOT INT (RND *3) THEN GO TO 4250
4220 BORDER 5:PAPER 0:INK 7:FLASH 1:GO SUB cls:FLASH 0:INK 9
4224 PRINT AT 6,3;"NEBEZPECI VALKY S LEFTOTEM"
4226 PRINT AT 10,3;"Vase popularita v RITIMBANU";AT 12,12;"STOUPNE"
4230 POKE 23886,255:FOR a=1 TO 5:LET i=USR 23884:NEXT a
4234 FOR a=1 TO 3:GO SUB 4242:NEXT a
4236 LET a=6:GO SUB 4242
4240 RETURN
4242 IF g$(a,1)<"9" THEN LET g$(a,1)=STR$ (VAL g$(a,1)+1)
4244 RETURN
4250 REM actual
4270 PAPER 2:BORDER 0:GO SUB cls:PRINT AT 8,7;" INVAZE Z LEFTOTA "
4276 LET rs=0:FOR a=1 TO 3:IF VAL g$(a,1)>low THEN LET rs=rs+VAL g$(a,2)
4278 NEXT a
4280 IF VAL g$(6,1)>low THEN LET rs=rs+VAL g$(6,2)
4282 LET rs=rs+st
4286 PRINT AT 12,5;"Sila RITIMBANU je ";rs
4290 LET ls=0:FOR a=1 TO 6:IF VAL g$(a,1)<= low THEN LET ls=ls+VAL g$(a,2)
4292 NEXT a
4294 PRINT AT 14,5;"Sila LEFTOTA je ";ls
4296 PRINT AT 18,4;"KRATKA ROZHODUJICI VALKA"
4298 GO SUB 10
4300 IF ls+INT (RND *3-1)>= rs THEN GO TO 4320
4310 POKE 23886,50:BORDER 0:GO SUB cls:PRINT AT 12,6;" LEFTOTANE VYHNANI ":LET i=USR 23842
4312 LET g$(5,2)="0":RETURN
4320 BORDER 0:PAPER 0:GO SUB cls
4321 PRINT AT 7,6;" VITEZSTVI LEFTOTA "
4323 POKE 23886,255:FOR a=1 TO 5:LET i=USR 23884:NEXT a
4324 IF d$(36,1)="*"AND INT (RND *3) THEN GO TO 4340
4326 LET d=0:IF d$(36,1)="*" THEN PRINT AT 10,6;"PORUCHA HELIKOPTERY":PAUSE 80
4327 PRINT AT 12,5;"Byl jste odsouzen jako"''" NEPRITEL LIDU a..."
4328 PAUSE 30:GO SUB 70:PRINT AT 18,7;"Okamzite POPRAVEN"
4330 RETURN
4340 GO SUB cls:PRINT AT 12,3;"Unikl jste HELIKOPTEROU !":POKE 23886,70:LET i=USR 23842:LET esc=1:RETURN
5000 REM COY
5006 PRINT AT 20,11;PAPER 7;" ""A""= ANO "
5010 IF INKEY$ <> "" THEN GO TO 5010
5012 PRINT AT 21,0;PAPER 2;s$;" KLAVESU ";s$
5014 FOR a=1 TO 15
5015 IF INKEY$ <> "" THEN GO TO 5030
5016 NEXT a
5017 BEEP .01,30
5018 PRINT AT 21,0;PAPER 1;s$;" KLAVESU ";s$
5019 FOR a=1 TO 15
5020 IF INKEY$ <> "" THEN GO TO 5030
5024 NEXT a
5025 BEEP .01,20
5026 GO TO 5012
5030 LET k$=INKEY$ :IF k$="" THEN GO TO 5018
5032 IF k$="y" THEN LET k$="n"
5033 IF k$="a" THEN LET k$="y"
5034 IF k$="y" THEN BEEP .25,30
5036 IF k$<> "y" THEN BEEP .25,10
5037 IF k$="#" THEN POKE 23659,2:PAPER 7:BORDER 7:STOP
5100 RETURN
6000 REM DATA
6101 DATA "NMHQJLMMMMMPKLMMM VSEOBECNOU BRANNOU POVINNOST "
6102 DATA "NMMPMJMMMMMNMLMMMzabavit PUDU pro CVICENI ARMADY "
6103 DATA "NCMPLNMLMLMNMNIMM ZAUTOCIT na VSECHNY PARTIZANY "
6104 DATA "NEMPLMMIMLMNMNKMMZAUTOCIT na PARTIZANY v LEFTOTU "
6105 DATA "NMMQONMMIMMNMNMMJ PROPUSTIT sefa TAJNE POLICIE "
6106 DATA "NMMPMMMLMIOMMMMMMVYHNAT RUSKE VOJEN. POZOROVATELE"
6107 DATA "NMDQMLMMMMMOLLLMM zvysit ZOLD ARMADE "
6108 DATA "NAMQLLMLLMMPLLKLMnakoupit vice ZBRANI a STRELIVA "
6109 DATA "NMMLONMMMMMLMMLMMaby k nim VOJACI byli slusnejsi"
6110 DATA "NMMMQIMNMMMMOLMMM zvysit DOLNI HRANICI MEZD "
6111 DATA "NMPNQOMMIMMNNNNMJ snizit MOC TAJNE POLICIE "
6112 DATA "NMMMPKMKMMMMOKMMM neprijimat delniky z LEFTOTA "
6113 DATA "NCELQKMOLNMMNLLMM BEZPLATNOU SKOLNI DOCHAZKU "
6114 DATA "NMMMQJMNLNMMPJMML LEGALIZOVAT jejich ODBORY "
6115 DATA "NMMLQKMNLMMMOLLMMPROPUSTIT JEJICH VUDCE z vezeni "
6116 DATA "NMSMPLMMMMMMMMLMM usporadat LIDOVOU LOTERII"
6117 DATA "NMMKMPMMMMMLMMMMM zakazat VOJENSKE VYUZITI PUDY"
6118 DATA "NMMMIQMLMLMMKONMM snizit DOLNI HRANICI MEZD"
6119 DATA "NWHMMPMNMOIMMNMMM ZNARODNIT AMERICKY OBCHOD"
6120 DATA "NMRMMPMJMLMMNOMLMvybirat clo za IMPORT z LEFTOTA"
6121 DATA "NMQNNPMMIMMNMNNMKsnizit vydaje na TAJNOU POLICII"
6122 DATA "NMHMMQMMMMMMMOMMM snizit VELKY NAJEM za PUDU"
6123 DATA "NMMKLPMMMMMLLNNMMaby vojaci PRACOVALI na POLICH"
6124 DATA "NACNNPMJMONMMPMKMvybudovat VELKY ZAVLAHOVY SYSTEM"
6125 DATA "NMMQLLMMLMMNMMLMLPOVYSIT SEFA ARMADY"
6126 DATA "NLILQNMOMNMMMMLMMZMENSIT LEKARSKE POPLATKY"
6127 DATA "NMMLKQMMLLMLLOMMLdat STATKARUM REGIONALNI PRAVA"
6128 DATA "NRMKMMMQMKNLMMLPMprodat AMERICANY do LEFTOTA"
6129 DATA "NYMMMLMLMKPMMMMMMprodat DOLY AMERICKYM FIRMAM"
6130 DATA "NMWKMMMMMPJMMMMNMpronajat RUSUM NAMORNI ZAKLADNU"
6131 DATA "NMENPPMMMMMLMMLMMzmensit DANE"
6132 DATA "NEMPPPMMMMMMMMLMMkampan na ZVYSENI POPULARITY"
6133 DATA "NMUPPPMMDMMONNNMDkompletne SNIZIT silu POLICIE"
6134 DATA "NMGJJJMMUMMLLLLMUZVYSIT silu TAJNE POLICIE"
6135 DATA "NIMKLLMMLMMKMMMMLZVETSIT svou TELESNOU STRAZ *"
6136 DATA "NAMIIJMMKMMMMMMMMkoupit si UNIKOVOU HELIKOPTERU"
6137 DATA "NMMMMMMMMMMMMMMMMprevest najake PENIZE do SVYCAR*"
6138 DATA "NMMMMMMMMMMMMMMMMpozadat RUSY o ""PUJCKU"""
6139 DATA "NMMMMMMMMMMMMMMMMpozadat AMERICANY o ""VYPOMOC"""
6140 DATA "NZMNNPMGMKMMMMMMMZNARODNIT LEFTOTANSKY OBCHOD"
6141 DATA "NHMPMMMJMLMRMMKKLkoupit ZBRANE pro ARMADU"
6142 DATA "NMMMPLMMLMMMRLPMLdovolit ROLNIKUM volny pohyb"
6143 DATA "NMMLLPMMLMMLLRLMLpovolit STATKARUM vlastni MILICI"
6144 DATA "NMMMMMMMIMMMMMQMIPRESIDENT ZTRATIL POLICEJNI AKTA"
6145 DATA "NMMMMMMMMMMLMMVMMPARTYZANI dostali ZBRANE z KUBY"
6146 DATA "NMMMMMMMMMMIMMOMNINCIDENT. ARMADNI SKLAD VYBUCHL"
6147 DATA "NMMMMMMMMMMMMJMKM ceny BANANU KLESLY o 98%"
6148 DATA "NMMMMMMMMMMMMOMIM velke ZEMETRESENI v LEFTOTU"
6149 DATA "NMMMMMMMMMMMILKMM epidemie MORU mezi ROLNIKY"
6150 DATA "76::"+CHR$ 31+"VOJACI"
6151 DATA "76:: ROLNICI"
6152 DATA "76::!STATKARI"
6153 DATA "06--"+CHR$ 34+"PARTYZANI"
6154 DATA "76--"+CHR$ 34+"LEFTOTANE"
6155 DATA "76--&TAJNA POLICIE"
6156 DATA "7---"+CHR$ 31+"RUSOVE"
6157 DATA "7---"+CHR$ 34+"AMERICANE"
6200 DATA " ARMADA "," ROLNICI "," STATKARI ","PARTYZANI "
6210 DATA "LEFTOTANE ","T.POLICIE "," RUSOVE ","AMERICANE "
7000 REM SAVE
7010 SAVE "dictator"CODE 22528,25200
7012 IF INKEY$ ="q" THEN GO TO 7050
7046 GO TO 80
7050 IF INKEY$ <> "" THEN GO TO 7050
7060 CLEAR :INK 7:BORDER 7:PAPER 7:CLS :POKE 23886
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment