Fast 'shell:startup' and Task Scheduler Auto Application Startup replacement using AutoHotkey

README.md

Auto Executor

The compiled 'AutoExecutor.exe' file SHORTCUT (.lnk) is meant to be placed inside 'shell:startup' directory.
This would launch AutoExecutor.exe upon windows startup, which in turn would start launching applications inside 'Apps' folder.

How it works:

The script searches for .exe, .lnk and .ahk files inside 'Apps' folder. Once found, it checks if the filename doesn't contain specific rules. The currently available rules are:

• #milliseconds_FILENAME.exe - which would delay the launch of this specific FILENAME.exe by an X amount of time in milliseconds.
  • For example: "#3000_ThrottleStop.exe" would launch 'ThrottleStop.exe' after 3 seconds.

Note, that the 'Apps' folder has to be relative to the 'AutoExecutor.exe' script file.

Features:

• Launch applications in administrator privileges
• Auto Start applications inside 'Apps' folder
• Customize application launch time
  • To use this feature, add a prefix to file names inside 'Apps' folder.

AutoExecutor.ahk

#NoEnv
#SingleInstance Force
#NoTrayIcon

SetBatchLines, -1
SetKeyDelay, -1, 1
SetMouseDelay, -1
SetWinDelay, -1
SetControlDelay, -1

class Utility {
	RequireAdmin() {
		FULL_COMMAND_LINE := DllCall("GetCommandLine", "str")
		if not (A_IsAdmin or RegExMatch(FULL_COMMAND_LINE, " /restart(?!\S)")) {
			try {
				FilePath := ""
				if A_IsCompiled
					FilePath := A_ScriptFullPath
				else
					FilePath := Format("{} /restart \\\""{}\\\""", A_AhkPath, A_ScriptFullPath)
				
				psScript =
				(
					param($param1)
					Start-Process powershell -WindowStyle Hidden -Verb RunAs -ArgumentList \"-Command Start-Process '$param1'\"
				)
				
				psScript := Format("powershell -Command &{{1}} '{2}'", psScript, FilePath)
										
				RunWait, % psScript,, Hide
			}
			ExitApp
		}
	}
	
	SetTimer(fn, period := -1) {
		SetTimer % fn, % period
	}
}

class AutoExecutor {
	static FolderName := "Apps"
	static ExtensionPattern := "exe|lnk|ahk"
	
	static _ := AutoExecutor := new AutoExecutor()
	
	__New() {
		Utility.RequireAdmin()
		
		this.Initialize()
	}
	
	Config() {		
		this.ExitManager := new this.ExitManager()
		
		this.Pattern := "i).*\.(" . this.ExtensionPattern . ")$"
		this.SearchPath := A_ScriptDir . "\" . this.FolderName . "\*"
	}
	
	Initialize() {
		this.Config()
		
		this.Search(this.SearchPath)
		
		this.Finalize()
	}
	
	Search(SearchPath) {
		Loop, Files, % SearchPath
		{
			FileFullPath := A_LoopFileFullPath
			
			if !RegExMatch(FileFullPath, this.Pattern)
				continue
				
			FileName := A_LoopFileName
			SleepMatch := RegExMatch(FileName, "#(\d+)_", SleepMatch)
			SleepTime := SleepMatch ? SleepMatch1 : ""
			
			if (SleepTime > 0) {
				this.LaunchAppDelayed(FileFullPath, SleepTime)
			} else {
				this.LaunchApp(FileFullPath)
			}			
			
		}
	}
	
	LaunchAppDelayed(FileFullPath, Delay := 1) {
		this.ExitManager.QueueExecution()

		Utility.SetTimer(ObjBindMethod(this, "_ExitManagedLaunchApp", FileFullPath), -1 * Delay)
	}
	
	_ExitManagedLaunchApp(FileFullPath) {				
		this.LaunchApp(FileFullPath)
		
		this.ExitManager.FinishExecution()
	}
	
	LaunchApp(FileFullPath) {
		DllCall("Shell32\ShellExecute", "UInt", 0, "Str", "open", "Str", FileFullPath, "Str", "", "Str", "", "Int", 1)
	}
	
	Finalize() {
		this.ExitManager.AttemptExit()
	}
	
	class ExitManager {
		__New() {
			this.TOTAL_EXECUTIONS := 0
			
			this.ExitFn := ObjBindMethod(this, "AttemptExit")
		}
		
		QueueExecution() {
			this.TOTAL_EXECUTIONS++
		}
		
		FinishExecution() {
			this.TOTAL_EXECUTIONS--
		}
		
		AttemptExit() {
			if (this.TOTAL_EXECUTIONS > 0) {
				Utility.SetTimer(this.ExitFn, -1000)
				return
			}				
			
			this.Exit()
		}
	
		Exit() {
			ExitApp
		}
	}
}

#If (WinActive("ahk_exe notepad++.exe") || WinActive("ahk_exe code.exe"))
^R::Reload