Script para serializar Adobe Acrobat DC usando adobe_prtk.exe

adobe_prtk.bat

@echo off

setlocal

echo Copiando 'AdobeExpiryCheck.exe' a '%temp%' ...
copy /y AdobeExpiryCheck.exe %temp% > nul

echo Copiando 'adobe_prkt.exe' a '%temp%' ...
copy /y adobe_prtk.exe %temp% > nul

echo Comprobando fecha licencia Adobe Acrobat ...
"%temp%\AdobeExpiryCheck.exe"

:: Download & Docs
:: https://helpx.adobe.com/acrobat/kb/how-to-Re-Serialize-Acrobat-using-the-APTEE-tool.html
:: https://helpx.adobe.com/enterprise/kb/provisioning-toolkit-enterprise.html
:: https://gist.github.com/bhunut-adobe/b7ff3ec8f5957b7cbe60bd944a748d25

set serial=xxxx-xxxx-xxxx-xxxx-xxxx-xxxx

:: Acrobat (ETLA serial key)
set leid=V7{}AcrobatCont-12-Win-GM

:: Acrobat (ETLA serial key) - To be used only in unserialize command
set unleid=V7{}AcrobatETLA-12-Win-GM

:: Acrobat Classic 2020
:: set unleid=V7{}AcrobatESR-20-Win-GM

echo Generando 'prov.xml' usando 'serial=%serial%' y 'leid=%leid%...
"%temp%\adobe_prtk.exe" --tool=VolumeSerialize --generate --serial=%serial% --leid=%leid% --regsuppress=ss --eulasuppress >nul 2>&1

echo Deserializando 'leid=%unleid%...
"%temp%\adobe_prtk.exe" --tool=UnSerialize --leid=%unleid% --deactivate --force

if exist "%temp%\prov.xml" (
	echo Serializando 'Volume Serialize' con '%temp%\prov.xml' ...
	"%temp%\adobe_prtk.exe" --tool=VolumeSerialize --provfile="%temp%\prov.xml" --stream >nul 2>&1
) else (
	echo No se ha encontrado el fichero '%temp%\prov.xml'!
)

echo Comprobando fecha licencia Adobe Acrobat ...
"%temp%\AdobeExpiryCheck.exe"

echo Limpiando ...
del "%temp%\AdobeExpiryCheck.exe" >nul 2>&1
del "%temp%\adobe_prtk.exe" >nul 2>&1
del "%temp%\prov.xml" >nul 2>&1

endlocal