Using android-junit5 with gradle/kotlin-dsl. https://github.com/mannodermaus/android-junit5

build.gradle.kts

import de.mannodermaus.gradle.plugins.junit5.*
import org.junit.platform.console.options.Details

plugins {
  // 1. Declare plugin
  id("de.mannodermaus.android-junit5") version "1.0.30"
  
  // More plugins here (Kotlin, Android)
}

android {
  testOptions {
    // 2. Access DSL (example)
    junitPlatform.apply {
      details = Details.TREE
    }
  }
}

dependencies {
  // 3. Declare dependencies
  // For some odd reason, Kotlin's dependency handler doesn't allow
  // to add lists of dependencies using DependencyHandler#add().
  // Therefore, iterate over the custom handler's dependency groups & add them one by one instead.
  val junit5 = dependencies.ext["junit5"] as JUnit5DependencyHandler
  junit5.unitTests().forEach { testCompile(it) }
  junit5.parameterized().forEach { testCompile(it) }
}

repositories {
  jcenter()
  google()
}

settings.gradle.kts

pluginManagement {
  repositories {
    gradlePluginPortal()
    google()
  }
  resolutionStrategy {
    eachPlugin {
      // 4. Manually map plugin coordinates
      if (requested.id.id == "de.mannodermaus.android-junit5") {
        useModule("de.mannodermaus.gradle.plugins:android-junit5:${requested.version}")
      }
    }
  }
}

rootProject.buildFileName = "build.gradle.kts"