Fetch Crystal dependencies on the lfy

ifd-lock.nix

{ pkgs ? import ./nix { } }:

let
  inherit (builtins) fromJSON readFile toFile elemAt split mapAttrs;
  inherit (pkgs)
    crystal runCommand stdenv lib coreutils inclusive pkgconfig openssl;
  inherit (pkgs.lib) makeBinPath;

  shardLock2JSON = shardLockFile:
    runCommand "yaml2json" { buildInputs = [ crystal ]; } ''
      crystal eval <<-EOF > $out
        require "json"
        require "yaml"

        puts YAML.parse(File.read("${shardLockFile}")).to_json
      EOF
    '';

  fetchShards = shardLockFile:
    mapAttrs (name: value:
      let
        parts = split "\\+git\\.commit\\." value.version;
        version = elemAt parts 0;
        rev = elemAt parts 2;
      in fetchGit {
        url = value.git;
        rev = rev;
      }) (fromJSON (readFile (shardLock2JSON shardLockFile))).shards;

  shardsDir = shardLockFile:
    stdenv.mkDerivation {
      name = "shard-libs";
      __structuredAttrs = true;
      preferLocalBuild = true;
      PATH = lib.makeBinPath [ coreutils ];
      shards = fetchShards shardLockFile;
      builder = toFile "builder" ''
        . .attrs.sh
        out=''${outputs[out]}
        mkdir $out

        for name in "''${!shards[@]}"; do
          echo "Linking shard $name ..."
          ln -s "''${shards[$name]}" "$out/$name"
        done
      '';
    };

in crystal.buildCrystalPackage {
  pname = "example";
  version = "0.1.0";
  format = "crystal";
  buildInputs = [ pkgconfig openssl ];
  src = inclusive ./. [ ./src ];

  preConfigure = ''
    ln -s ${shardsDir ./shard.lock} lib
  '';

  crystalBinaries.example.src = "src/example.cr";
}